becca.monster
forked from
tangled.org/core
Monorepo for Tangled
22 kB
620 lines
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 # strange errors in console that i can't really make out
32 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
33 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
34 flake = false;
35 };
36 lucide-src = {
37 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
38 flake = false;
39 };
40 inter-fonts-src = {
41 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
42 flake = false;
43 };
44 actor-typeahead-src = {
45 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
46 flake = false;
47 };
48 mermaid-src = {
49 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
50 flake = false;
51 };
52 hls-src = {
53 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
54 flake = false;
55 };
56 mathjax-src = {
57 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
58 flake = false;
59 };
60 ibm-plex-mono-src = {
61 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
62 flake = false;
63 };
64 sqlite-lib-src = {
65 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
66 flake = false;
67 };
68 fetch-tangled = {
69 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
70 inputs.nixpkgs.follows = "nixpkgs";
71 };
72 };
73
74 outputs = {
75 self,
76 nixpkgs,
77 fenix,
78 gomod2nix,
79 indigo,
80 htmx-src,
81 htmx-ws-src,
82 lucide-src,
83 inter-fonts-src,
84 sqlite-lib-src,
85 ibm-plex-mono-src,
86 actor-typeahead-src,
87 mermaid-src,
88 hls-src,
89 microvm,
90 fetch-tangled,
91 mathjax-src,
92 ...
93 }: let
94 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
95 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
96 nixpkgsFor = forAllSystems (system:
97 import nixpkgs {
98 inherit system;
99 overlays = [fetch-tangled.overlays.default];
100 });
101
102 mkPackageSet = pkgs:
103 pkgs.lib.makeScope pkgs.newScope (self: {
104 src = let
105 fs = pkgs.lib.fileset;
106 in
107 fs.toSource {
108 root = ./.;
109 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
110 };
111 rustSrc = let
112 fs = pkgs.lib.fileset;
113 in
114 fs.toSource {
115 root = ./.;
116 fileset =
117 fs.intersection
118 (fs.fromSource self.src)
119 (fs.unions [
120 ./Cargo.toml
121 ./Cargo.lock
122 ./shuttle
123 ./bobbin
124 ]);
125 };
126 buildGoApplication =
127 (self.callPackage "${gomod2nix}/builder" {
128 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
129 }).buildGoApplication;
130 rustPlatform = pkgs.makeRustPlatform {
131 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
132 };
133 rustPlatformStatic = let
134 system = pkgs.stdenv.hostPlatform.system;
135 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
136 toolchain = fenix.packages.${system}.combine [
137 fenix.packages.${system}.stable.cargo
138 fenix.packages.${system}.stable.rustc
139 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
140 ];
141 in
142 pkgs.pkgsStatic.makeRustPlatform {
143 cargo = toolchain;
144 rustc = toolchain;
145 };
146 modules = ./nix/gomod2nix.toml;
147 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
148 inherit sqlite-lib-src;
149 };
150 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
151 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
152 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
153 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src;
154 };
155 web-static-files = self.callPackage ./nix/pkgs/web-static-files.nix {
156 inherit inter-fonts-src ibm-plex-mono-src;
157 };
158 appview = self.callPackage ./nix/pkgs/appview.nix {};
159 blog = self.callPackage ./nix/pkgs/blog.nix {};
160 docs = self.callPackage ./nix/pkgs/docs.nix {
161 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
162 inherit (pkgs) pagefind;
163 };
164 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
165 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
166 src = self.rustSrc;
167 };
168 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
169 src = self.rustSrc;
170 rustPlatform = self.rustPlatformStatic;
171 };
172 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
173 knot = self.callPackage ./nix/pkgs/knot.nix {};
174 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
175 tap = self.callPackage ./nix/pkgs/tap.nix {};
176 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
177 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
178 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
179 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
180 });
181 in {
182 overlays.default = final: prev: {
183 inherit
184 (mkPackageSet final)
185 lexgen
186 goat
187 sqlite-lib
188 spindle
189 shuttle
190 knot-unwrapped
191 knot
192 appview
193 docs
194 dolly
195 tap
196 knotmirror
197 bobbin
198 zoekt-webserver
199 zoekt-tngl-indexserver
200 ;
201 };
202
203 packages = forAllSystems (system: let
204 pkgs = nixpkgsFor.${system};
205 linuxPkgs = nixpkgsFor."x86_64-linux";
206 packages = mkPackageSet pkgs;
207 staticPackages = mkPackageSet pkgs.pkgsStatic;
208 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
209 in {
210 inherit
211 (packages)
212 appview
213 appview-static-files
214 web-static-files
215 blog
216 lexgen
217 goat
218 spindle
219 knot
220 knot-unwrapped
221 sqlite-lib
222 docs
223 shuttle
224 shuttle-static
225 dolly
226 tap
227 knotmirror
228 bobbin
229 zoekt-webserver
230 zoekt-tngl-indexserver
231 ;
232
233 pkgsStatic-appview = staticPackages.appview;
234 pkgsStatic-knot = staticPackages.knot;
235 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
236 pkgsStatic-spindle = staticPackages.spindle;
237 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
238 pkgsStatic-dolly = staticPackages.dolly;
239
240 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
241 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
242 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
243 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
244 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
245
246 treefmt-wrapper = pkgs.treefmt.withConfig {
247 settings.formatter = {
248 alejandra = {
249 command = pkgs.lib.getExe pkgs.alejandra;
250 includes = ["*.nix"];
251 };
252
253 gofmt = {
254 command = pkgs.lib.getExe' pkgs.go "gofmt";
255 options = ["-w"];
256 includes = ["*.go"];
257 };
258
259 rustfmt = {
260 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
261 options = ["--edition" "2024"];
262 includes = ["*.rs"];
263 excludes = ["**/src/_lex/**"];
264 };
265
266 # prettier = let
267 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
268 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
269 # '';
270 # in {
271 # command = wrapper;
272 # options = ["-w"];
273 # includes = ["*.html"];
274 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
275 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
276 # };
277 };
278 };
279
280 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
281 nixosSystem = self.nixosConfigurations.spindle-nixos;
282 };
283 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
284 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
285 '';
286
287 spindle-alpine-image = let
288 branch = "3.24";
289 version = "${branch}.0";
290 arch = "x86_64";
291 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
292
293 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
294 in
295 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
296 inherit arch shuttle;
297 repositories = [
298 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
299 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
300 ];
301 rootfs = linuxPkgs.fetchurl {
302 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
303 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
304 };
305 kernel = linuxPkgs.fetchurl {
306 url = "${cdn}/netboot-${version}/vmlinuz-virt";
307 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
308 };
309 initramfs = linuxPkgs.fetchurl {
310 url = "${cdn}/netboot-${version}/initramfs-virt";
311 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
312 };
313 modloop = linuxPkgs.fetchurl {
314 url = "${cdn}/netboot-${version}/modloop-virt";
315 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
316 };
317 };
318 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
319 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
320 '';
321 });
322 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
323 devShells = forAllSystems (system: let
324 pkgs = nixpkgsFor.${system};
325 packages' = self.packages.${system};
326 staticShell = args:
327 (pkgs.mkShell.override {
328 stdenv = pkgs.pkgsStatic.stdenv;
329 }) (args
330 // {
331 nativeBuildInputs =
332 args.nativeBuildInputs
333 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
334 pkgs.darwin.cctools
335 ];
336 });
337 in {
338 default = staticShell {
339 nativeBuildInputs =
340 [
341 pkgs.go
342 pkgs.air
343 pkgs.gopls
344 pkgs.httpie
345 pkgs.litecli
346 pkgs.websocat
347 pkgs.tailwindcss
348 pkgs.nixos-shell
349 pkgs.redis
350 pkgs.worker-build
351 pkgs.cargo-generate
352 pkgs.qemu
353 pkgs.cdrkit
354 pkgs.buf
355 pkgs.protobuf
356 pkgs.protoc-gen-prost
357 pkgs.protoc-gen-prost-crate
358 pkgs.protoc-gen-prost-serde
359 pkgs.protoc-gen-go
360 (fenix.packages.${system}.combine [
361 fenix.packages.${system}.stable.cargo
362 fenix.packages.${system}.stable.rustc
363 fenix.packages.${system}.stable.rust-src
364 fenix.packages.${system}.stable.clippy
365 fenix.packages.${system}.stable.rustfmt
366 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
367 ])
368 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
369 packages'.lexgen
370 packages'.treefmt-wrapper
371 packages'.tap
372 pkgs.e2fsprogs
373 pkgs.util-linux
374 pkgs.pnpm
375 ]
376 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
377 pkgs.parted
378 pkgs.slirp4netns
379 pkgs.iproute2
380 ];
381 shellHook = ''
382 export CC=${pkgs.stdenv.cc}/bin/cc
383 mkdir -p appview/pages/static
384 # temporary self-heal for workspaces that copied static assets as read-only
385 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
386 # no preserve is needed because watch-tailwind will want to be able to overwrite
387 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
388 mkdir -p web/static
389 rm -rf web/static/fonts web/static/logos
390 cp -fr --no-preserve=ownership,mode ${packages'.web-static-files}/* web/static
391 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
392 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
393 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
394 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
395 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
396 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
397 fi
398 '';
399 env.CGO_ENABLED = 1;
400 };
401 });
402 apps = forAllSystems (system: let
403 pkgs = nixpkgsFor."${system}";
404 packages' = self.packages.${system};
405 air-watcher = name: arg:
406 pkgs.writeShellScriptBin "run"
407 ''
408 export PATH=${pkgs.go}/bin:$PATH
409 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
410 -build.args_bin "${arg}"
411 '';
412 tailwind-watcher =
413 pkgs.writeShellScriptBin "run"
414 ''
415 export BROWSERSLIST_IGNORE_OLD_DATA=true
416 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
417 '';
418 in {
419 watch-appview = {
420 type = "app";
421 program = toString (pkgs.writeShellScript "watch-appview" ''
422 echo "copying static files to appview/pages/static..."
423 mkdir -p appview/pages/static
424 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
425 ${air-watcher "appview" ""}/bin/run
426 '');
427 };
428 watch-knot = {
429 type = "app";
430 program = ''${air-watcher "knot" "server"}/bin/run'';
431 };
432 watch-spindle = {
433 type = "app";
434 program = ''${air-watcher "spindle" ""}/bin/run'';
435 };
436 watch-blog = {
437 type = "app";
438 program = toString (pkgs.writeShellScript "watch-blog" ''
439 echo "copying static files to appview/pages/static..."
440 mkdir -p appview/pages/static
441 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
442 ${air-watcher "blog" "serve"}/bin/run
443 '');
444 };
445 watch-tailwind = {
446 type = "app";
447 program = ''${tailwind-watcher}/bin/run'';
448 };
449 serve-docs = {
450 type = "app";
451 program = toString (pkgs.writeShellScript "serve-docs" ''
452 echo "building docs..."
453 docsOut=$(nix build --no-link --print-out-paths .#docs)
454 echo "serving docs at http://localhost:1414"
455 cd "$docsOut"
456 exec ${pkgs.python3}/bin/python3 -m http.server 1414
457 '');
458 };
459 regenerate-proto = {
460 type = "app";
461 program =
462 (pkgs.writeShellApplication {
463 name = "regenerate-proto";
464 runtimeInputs = with pkgs; [git buf coreutils];
465 text = ''
466 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
467 cd "$rootDir"
468 echo ">>> regenerating protobuf files.."
469 buf generate
470 echo ">>> generating file descriptor set for shuttle..."
471 buf build -o shuttle/src/gen/file_descriptor_set.bin
472 echo ">>> done"
473 '';
474 })
475 + "/bin/regenerate-proto";
476 };
477 vm = let
478 guestSystem =
479 if pkgs.stdenv.hostPlatform.isAarch64
480 then "aarch64-linux"
481 else "x86_64-linux";
482 in {
483 type = "app";
484 program =
485 (pkgs.writeShellApplication {
486 name = "launch-vm";
487 text = ''
488 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
489 cd "$rootDir"
490
491 # Reset TMPDIR in case it points to a stale nix-shell temp dir
492 export TMPDIR=/tmp
493
494 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
495
496 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
497 exec ${pkgs.lib.getExe
498 (import ./nix/vm.nix {
499 inherit nixpkgs self;
500 system = guestSystem;
501 hostSystem = system;
502 }).config.system.build.vm}
503 '';
504 })
505 + /bin/launch-vm;
506 };
507 gomod2nix = {
508 type = "app";
509 program = toString (pkgs.writeShellScript "gomod2nix" ''
510 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
511 '');
512 };
513 lexgen = {
514 type = "app";
515 program =
516 (pkgs.writeShellApplication {
517 name = "lexgen";
518 text = ''
519 if ! command -v lexgen > /dev/null; then
520 echo "error: must be executed from devshell"
521 exit 1
522 fi
523
524 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
525 cd "$rootDir"
526
527 # *_ext.go are hand-written extensions; never remove or mutate them
528 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
529 lexgen --build-file lexicon-build-config.json lexicons
530
531 # disable type registration temporarily while running cborgen
532 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
533 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
534 # lexgen generates incomplete Marshaler/Unmarshaler for union types
535 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -not -name "cbor_gen.go" -exec \
536 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
537 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
538 ${pkgs.gotools}/bin/goimports -w api/tangled/*
539 CGO_ENABLED=0 go run ./cmd/cborgen/
540 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
541
542 lexgen --build-file lexicon-build-config.json lexicons
543 rm api/tangled/*.bak
544 '';
545 })
546 + /bin/lexgen;
547 };
548 });
549
550 nixosModules.appview = {
551 lib,
552 pkgs,
553 ...
554 }: {
555 imports = [./nix/modules/appview.nix];
556
557 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
558 };
559 nixosModules.knotmirror = {
560 lib,
561 pkgs,
562 ...
563 }: {
564 imports = [./nix/modules/knotmirror.nix];
565
566 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
567 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
568 };
569 nixosModules.zoekt-tnglserver = {
570 lib,
571 pkgs,
572 ...
573 }: {
574 imports = [./nix/modules/zoekt-tnglserver.nix];
575
576 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
577 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
578 };
579 nixosModules.knot = {
580 lib,
581 pkgs,
582 ...
583 }: {
584 imports = [./nix/modules/knot.nix];
585
586 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
587 };
588 nixosModules.spindle = {
589 lib,
590 pkgs,
591 ...
592 }: {
593 imports = [./nix/modules/spindle.nix];
594
595 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
596 };
597 nixosModules.shuttle = {
598 lib,
599 pkgs,
600 ...
601 }: {
602 imports = [./nix/modules/shuttle.nix];
603
604 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
605 };
606
607 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
608
609 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
610
611 nixosConfigurations = let
612 spindleNixosBase = nixpkgs.lib.nixosSystem {
613 system = "x86_64-linux";
614 modules = [self.nixosModules.spindle-nixos];
615 };
616 in {
617 spindle-nixos = spindleNixosBase;
618 };
619 };
620}