becca.monster
forked from
tangled.org/core
Monorepo for Tangled
22 kB
611 lines
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 # strange errors in console that i can't really make out
32 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
33 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
34 flake = false;
35 };
36 lucide-src = {
37 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
38 flake = false;
39 };
40 inter-fonts-src = {
41 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
42 flake = false;
43 };
44 actor-typeahead-src = {
45 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
46 flake = false;
47 };
48 mermaid-src = {
49 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
50 flake = false;
51 };
52 hls-src = {
53 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
54 flake = false;
55 };
56 mathjax-src = {
57 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
58 flake = false;
59 };
60 ibm-plex-mono-src = {
61 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
62 flake = false;
63 };
64 sqlite-lib-src = {
65 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
66 flake = false;
67 };
68 fetch-tangled = {
69 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
70 inputs.nixpkgs.follows = "nixpkgs";
71 };
72 };
73
74 outputs = {
75 self,
76 nixpkgs,
77 fenix,
78 gomod2nix,
79 indigo,
80 htmx-src,
81 htmx-ws-src,
82 lucide-src,
83 inter-fonts-src,
84 sqlite-lib-src,
85 ibm-plex-mono-src,
86 actor-typeahead-src,
87 mermaid-src,
88 hls-src,
89 microvm,
90 fetch-tangled,
91 mathjax-src,
92 ...
93 }: let
94 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
95 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
96 nixpkgsFor = forAllSystems (system:
97 import nixpkgs {
98 inherit system;
99 overlays = [fetch-tangled.overlays.default];
100 });
101
102 mkPackageSet = pkgs:
103 pkgs.lib.makeScope pkgs.newScope (self: {
104 src = let
105 fs = pkgs.lib.fileset;
106 in
107 fs.toSource {
108 root = ./.;
109 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
110 };
111 rustSrc = let
112 fs = pkgs.lib.fileset;
113 in
114 fs.toSource {
115 root = ./.;
116 fileset =
117 fs.intersection
118 (fs.fromSource self.src)
119 (fs.unions [
120 ./Cargo.toml
121 ./Cargo.lock
122 ./shuttle
123 ./bobbin
124 ]);
125 };
126 buildGoApplication =
127 (self.callPackage "${gomod2nix}/builder" {
128 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
129 }).buildGoApplication;
130 rustPlatform = pkgs.makeRustPlatform {
131 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
132 };
133 rustPlatformStatic = let
134 system = pkgs.stdenv.hostPlatform.system;
135 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
136 toolchain = fenix.packages.${system}.combine [
137 fenix.packages.${system}.stable.cargo
138 fenix.packages.${system}.stable.rustc
139 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
140 ];
141 in
142 pkgs.pkgsStatic.makeRustPlatform {
143 cargo = toolchain;
144 rustc = toolchain;
145 };
146 modules = ./nix/gomod2nix.toml;
147 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
148 inherit sqlite-lib-src;
149 };
150 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
151 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
152 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
153 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src;
154 };
155 appview = self.callPackage ./nix/pkgs/appview.nix {};
156 blog = self.callPackage ./nix/pkgs/blog.nix {};
157 docs = self.callPackage ./nix/pkgs/docs.nix {
158 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
159 inherit (pkgs) pagefind;
160 };
161 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
162 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
163 src = self.rustSrc;
164 };
165 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
166 src = self.rustSrc;
167 rustPlatform = self.rustPlatformStatic;
168 };
169 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
170 knot = self.callPackage ./nix/pkgs/knot.nix {};
171 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
172 tap = self.callPackage ./nix/pkgs/tap.nix {};
173 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
174 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
175 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
176 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
177 });
178 in {
179 overlays.default = final: prev: {
180 inherit
181 (mkPackageSet final)
182 lexgen
183 goat
184 sqlite-lib
185 spindle
186 shuttle
187 knot-unwrapped
188 knot
189 appview
190 docs
191 dolly
192 tap
193 knotmirror
194 bobbin
195 zoekt-webserver
196 zoekt-tngl-indexserver
197 ;
198 };
199
200 packages = forAllSystems (system: let
201 pkgs = nixpkgsFor.${system};
202 linuxPkgs = nixpkgsFor."x86_64-linux";
203 packages = mkPackageSet pkgs;
204 staticPackages = mkPackageSet pkgs.pkgsStatic;
205 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
206 in {
207 inherit
208 (packages)
209 appview
210 appview-static-files
211 blog
212 lexgen
213 goat
214 spindle
215 knot
216 knot-unwrapped
217 sqlite-lib
218 docs
219 shuttle
220 shuttle-static
221 dolly
222 tap
223 knotmirror
224 bobbin
225 zoekt-webserver
226 zoekt-tngl-indexserver
227 ;
228
229 pkgsStatic-appview = staticPackages.appview;
230 pkgsStatic-knot = staticPackages.knot;
231 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
232 pkgsStatic-spindle = staticPackages.spindle;
233 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
234 pkgsStatic-dolly = staticPackages.dolly;
235
236 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
237 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
238 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
239 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
240 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
241
242 treefmt-wrapper = pkgs.treefmt.withConfig {
243 settings.formatter = {
244 alejandra = {
245 command = pkgs.lib.getExe pkgs.alejandra;
246 includes = ["*.nix"];
247 };
248
249 gofmt = {
250 command = pkgs.lib.getExe' pkgs.go "gofmt";
251 options = ["-w"];
252 includes = ["*.go"];
253 };
254
255 rustfmt = {
256 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
257 options = ["--edition" "2024"];
258 includes = ["*.rs"];
259 excludes = ["**/src/_lex/**"];
260 };
261
262 # prettier = let
263 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
264 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
265 # '';
266 # in {
267 # command = wrapper;
268 # options = ["-w"];
269 # includes = ["*.html"];
270 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
271 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
272 # };
273 };
274 };
275
276 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
277 nixosSystem = self.nixosConfigurations.spindle-nixos;
278 };
279 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
280 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
281 '';
282
283 spindle-alpine-image = let
284 branch = "3.24";
285 version = "${branch}.0";
286 arch = "x86_64";
287 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
288
289 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
290 in
291 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
292 inherit arch shuttle;
293 repositories = [
294 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
295 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
296 ];
297 rootfs = linuxPkgs.fetchurl {
298 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
299 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
300 };
301 kernel = linuxPkgs.fetchurl {
302 url = "${cdn}/netboot-${version}/vmlinuz-virt";
303 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
304 };
305 initramfs = linuxPkgs.fetchurl {
306 url = "${cdn}/netboot-${version}/initramfs-virt";
307 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
308 };
309 modloop = linuxPkgs.fetchurl {
310 url = "${cdn}/netboot-${version}/modloop-virt";
311 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
312 };
313 };
314 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
315 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
316 '';
317 });
318 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
319 devShells = forAllSystems (system: let
320 pkgs = nixpkgsFor.${system};
321 packages' = self.packages.${system};
322 staticShell = args:
323 (pkgs.mkShell.override {
324 stdenv = pkgs.pkgsStatic.stdenv;
325 }) (args
326 // {
327 nativeBuildInputs =
328 args.nativeBuildInputs
329 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
330 pkgs.darwin.cctools
331 ];
332 });
333 in {
334 default = staticShell {
335 nativeBuildInputs =
336 [
337 pkgs.go
338 pkgs.air
339 pkgs.gopls
340 pkgs.httpie
341 pkgs.litecli
342 pkgs.websocat
343 pkgs.tailwindcss
344 pkgs.nixos-shell
345 pkgs.redis
346 pkgs.worker-build
347 pkgs.cargo-generate
348 pkgs.qemu
349 pkgs.cdrkit
350 pkgs.buf
351 pkgs.protobuf
352 pkgs.protoc-gen-prost
353 pkgs.protoc-gen-prost-crate
354 pkgs.protoc-gen-prost-serde
355 pkgs.protoc-gen-go
356 (fenix.packages.${system}.combine [
357 fenix.packages.${system}.stable.cargo
358 fenix.packages.${system}.stable.rustc
359 fenix.packages.${system}.stable.rust-src
360 fenix.packages.${system}.stable.clippy
361 fenix.packages.${system}.stable.rustfmt
362 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
363 ])
364 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
365 packages'.lexgen
366 packages'.treefmt-wrapper
367 packages'.tap
368 pkgs.e2fsprogs
369 pkgs.util-linux
370 ]
371 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
372 pkgs.parted
373 pkgs.slirp4netns
374 pkgs.iproute2
375 ];
376 shellHook = ''
377 mkdir -p appview/pages/static
378 # temporary self-heal for workspaces that copied static assets as read-only
379 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
380 # no preserve is needed because watch-tailwind will want to be able to overwrite
381 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
382 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
383 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
384 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
385 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
386 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
387 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
388 fi
389 '';
390 env.CGO_ENABLED = 1;
391 };
392 });
393 apps = forAllSystems (system: let
394 pkgs = nixpkgsFor."${system}";
395 packages' = self.packages.${system};
396 air-watcher = name: arg:
397 pkgs.writeShellScriptBin "run"
398 ''
399 export PATH=${pkgs.go}/bin:$PATH
400 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
401 -build.args_bin "${arg}"
402 '';
403 tailwind-watcher =
404 pkgs.writeShellScriptBin "run"
405 ''
406 export BROWSERSLIST_IGNORE_OLD_DATA=true
407 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
408 '';
409 in {
410 watch-appview = {
411 type = "app";
412 program = toString (pkgs.writeShellScript "watch-appview" ''
413 echo "copying static files to appview/pages/static..."
414 mkdir -p appview/pages/static
415 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
416 ${air-watcher "appview" ""}/bin/run
417 '');
418 };
419 watch-knot = {
420 type = "app";
421 program = ''${air-watcher "knot" "server"}/bin/run'';
422 };
423 watch-spindle = {
424 type = "app";
425 program = ''${air-watcher "spindle" ""}/bin/run'';
426 };
427 watch-blog = {
428 type = "app";
429 program = toString (pkgs.writeShellScript "watch-blog" ''
430 echo "copying static files to appview/pages/static..."
431 mkdir -p appview/pages/static
432 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
433 ${air-watcher "blog" "serve"}/bin/run
434 '');
435 };
436 watch-tailwind = {
437 type = "app";
438 program = ''${tailwind-watcher}/bin/run'';
439 };
440 serve-docs = {
441 type = "app";
442 program = toString (pkgs.writeShellScript "serve-docs" ''
443 echo "building docs..."
444 docsOut=$(nix build --no-link --print-out-paths .#docs)
445 echo "serving docs at http://localhost:1414"
446 cd "$docsOut"
447 exec ${pkgs.python3}/bin/python3 -m http.server 1414
448 '');
449 };
450 regenerate-proto = {
451 type = "app";
452 program =
453 (pkgs.writeShellApplication {
454 name = "regenerate-proto";
455 runtimeInputs = with pkgs; [git buf coreutils];
456 text = ''
457 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
458 cd "$rootDir"
459 echo ">>> regenerating protobuf files.."
460 buf generate
461 echo ">>> generating file descriptor set for shuttle..."
462 buf build -o shuttle/src/gen/file_descriptor_set.bin
463 echo ">>> done"
464 '';
465 })
466 + "/bin/regenerate-proto";
467 };
468 vm = let
469 guestSystem =
470 if pkgs.stdenv.hostPlatform.isAarch64
471 then "aarch64-linux"
472 else "x86_64-linux";
473 in {
474 type = "app";
475 program =
476 (pkgs.writeShellApplication {
477 name = "launch-vm";
478 text = ''
479 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
480 cd "$rootDir"
481
482 # Reset TMPDIR in case it points to a stale nix-shell temp dir
483 export TMPDIR=/tmp
484
485 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
486
487 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
488 exec ${pkgs.lib.getExe
489 (import ./nix/vm.nix {
490 inherit nixpkgs self;
491 system = guestSystem;
492 hostSystem = system;
493 }).config.system.build.vm}
494 '';
495 })
496 + /bin/launch-vm;
497 };
498 gomod2nix = {
499 type = "app";
500 program = toString (pkgs.writeShellScript "gomod2nix" ''
501 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
502 '');
503 };
504 lexgen = {
505 type = "app";
506 program =
507 (pkgs.writeShellApplication {
508 name = "lexgen";
509 text = ''
510 if ! command -v lexgen > /dev/null; then
511 echo "error: must be executed from devshell"
512 exit 1
513 fi
514
515 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
516 cd "$rootDir"
517
518 # *_ext.go are hand-written extensions; never remove or mutate them
519 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
520 lexgen --build-file lexicon-build-config.json lexicons
521
522 # disable type registration temporarily while running cborgen
523 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
524 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
525 # lexgen generates incomplete Marshaler/Unmarshaler for union types
526 find api/tangled/*.go -not -name "cbor_gen.go" -exec \
527 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
528 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
529 ${pkgs.gotools}/bin/goimports -w api/tangled/*
530 CGO_ENABLED=0 go run ./cmd/cborgen/
531 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
532
533 lexgen --build-file lexicon-build-config.json lexicons
534 rm api/tangled/*.bak
535 '';
536 })
537 + /bin/lexgen;
538 };
539 });
540
541 nixosModules.appview = {
542 lib,
543 pkgs,
544 ...
545 }: {
546 imports = [./nix/modules/appview.nix];
547
548 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
549 };
550 nixosModules.knotmirror = {
551 lib,
552 pkgs,
553 ...
554 }: {
555 imports = [./nix/modules/knotmirror.nix];
556
557 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
558 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
559 };
560 nixosModules.zoekt-tnglserver = {
561 lib,
562 pkgs,
563 ...
564 }: {
565 imports = [./nix/modules/zoekt-tnglserver.nix];
566
567 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
568 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
569 };
570 nixosModules.knot = {
571 lib,
572 pkgs,
573 ...
574 }: {
575 imports = [./nix/modules/knot.nix];
576
577 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
578 };
579 nixosModules.spindle = {
580 lib,
581 pkgs,
582 ...
583 }: {
584 imports = [./nix/modules/spindle.nix];
585
586 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
587 };
588 nixosModules.shuttle = {
589 lib,
590 pkgs,
591 ...
592 }: {
593 imports = [./nix/modules/shuttle.nix];
594
595 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
596 };
597
598 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
599
600 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
601
602 nixosConfigurations = let
603 spindleNixosBase = nixpkgs.lib.nixosSystem {
604 system = "x86_64-linux";
605 modules = [self.nixosModules.spindle-nixos];
606 };
607 in {
608 spindle-nixos = spindleNixosBase;
609 };
610 };
611}