becca.monster
forked from
tangled.org/core
Monorepo for Tangled
22 kB
612 lines
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 # strange errors in console that i can't really make out
32 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
33 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
34 flake = false;
35 };
36 lucide-src = {
37 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
38 flake = false;
39 };
40 inter-fonts-src = {
41 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
42 flake = false;
43 };
44 actor-typeahead-src = {
45 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
46 flake = false;
47 };
48 mermaid-src = {
49 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
50 flake = false;
51 };
52 hls-src = {
53 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
54 flake = false;
55 };
56 mathjax-src = {
57 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
58 flake = false;
59 };
60 ibm-plex-mono-src = {
61 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
62 flake = false;
63 };
64 sqlite-lib-src = {
65 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
66 flake = false;
67 };
68 fetch-tangled = {
69 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
70 inputs.nixpkgs.follows = "nixpkgs";
71 };
72 };
73
74 outputs = {
75 self,
76 nixpkgs,
77 fenix,
78 gomod2nix,
79 indigo,
80 htmx-src,
81 htmx-ws-src,
82 lucide-src,
83 inter-fonts-src,
84 sqlite-lib-src,
85 ibm-plex-mono-src,
86 actor-typeahead-src,
87 mermaid-src,
88 hls-src,
89 microvm,
90 fetch-tangled,
91 mathjax-src,
92 ...
93 }: let
94 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
95 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
96 nixpkgsFor = forAllSystems (system:
97 import nixpkgs {
98 inherit system;
99 overlays = [fetch-tangled.overlays.default];
100 });
101
102 mkPackageSet = pkgs:
103 pkgs.lib.makeScope pkgs.newScope (self: {
104 src = let
105 fs = pkgs.lib.fileset;
106 in
107 fs.toSource {
108 root = ./.;
109 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
110 };
111 rustSrc = let
112 fs = pkgs.lib.fileset;
113 in
114 fs.toSource {
115 root = ./.;
116 fileset =
117 fs.intersection
118 (fs.fromSource self.src)
119 (fs.unions [
120 ./Cargo.toml
121 ./Cargo.lock
122 ./shuttle
123 ./bobbin
124 ]);
125 };
126 buildGoApplication =
127 (self.callPackage "${gomod2nix}/builder" {
128 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
129 }).buildGoApplication;
130 rustPlatform = pkgs.makeRustPlatform {
131 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
132 };
133 rustPlatformStatic = let
134 system = pkgs.stdenv.hostPlatform.system;
135 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
136 toolchain = fenix.packages.${system}.combine [
137 fenix.packages.${system}.stable.cargo
138 fenix.packages.${system}.stable.rustc
139 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
140 ];
141 in
142 pkgs.pkgsStatic.makeRustPlatform {
143 cargo = toolchain;
144 rustc = toolchain;
145 };
146 modules = ./nix/gomod2nix.toml;
147 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
148 inherit sqlite-lib-src;
149 };
150 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
151 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
152 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
153 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src;
154 };
155 appview = self.callPackage ./nix/pkgs/appview.nix {};
156 blog = self.callPackage ./nix/pkgs/blog.nix {};
157 docs = self.callPackage ./nix/pkgs/docs.nix {
158 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
159 inherit (pkgs) pagefind;
160 };
161 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
162 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
163 src = self.rustSrc;
164 };
165 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
166 src = self.rustSrc;
167 rustPlatform = self.rustPlatformStatic;
168 };
169 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
170 knot = self.callPackage ./nix/pkgs/knot.nix {};
171 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
172 tap = self.callPackage ./nix/pkgs/tap.nix {};
173 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
174 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
175 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
176 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
177 });
178 in {
179 overlays.default = final: prev: {
180 inherit
181 (mkPackageSet final)
182 lexgen
183 goat
184 sqlite-lib
185 spindle
186 shuttle
187 knot-unwrapped
188 knot
189 appview
190 docs
191 dolly
192 tap
193 knotmirror
194 bobbin
195 zoekt-webserver
196 zoekt-tngl-indexserver
197 ;
198 };
199
200 packages = forAllSystems (system: let
201 pkgs = nixpkgsFor.${system};
202 linuxPkgs = nixpkgsFor."x86_64-linux";
203 packages = mkPackageSet pkgs;
204 staticPackages = mkPackageSet pkgs.pkgsStatic;
205 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
206 in {
207 inherit
208 (packages)
209 appview
210 appview-static-files
211 blog
212 lexgen
213 goat
214 spindle
215 knot
216 knot-unwrapped
217 sqlite-lib
218 docs
219 shuttle
220 shuttle-static
221 dolly
222 tap
223 knotmirror
224 bobbin
225 zoekt-webserver
226 zoekt-tngl-indexserver
227 ;
228
229 pkgsStatic-appview = staticPackages.appview;
230 pkgsStatic-knot = staticPackages.knot;
231 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
232 pkgsStatic-spindle = staticPackages.spindle;
233 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
234 pkgsStatic-dolly = staticPackages.dolly;
235
236 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
237 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
238 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
239 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
240 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
241
242 treefmt-wrapper = pkgs.treefmt.withConfig {
243 settings.formatter = {
244 alejandra = {
245 command = pkgs.lib.getExe pkgs.alejandra;
246 includes = ["*.nix"];
247 };
248
249 gofmt = {
250 command = pkgs.lib.getExe' pkgs.go "gofmt";
251 options = ["-w"];
252 includes = ["*.go"];
253 };
254
255 rustfmt = {
256 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
257 options = ["--edition" "2024"];
258 includes = ["*.rs"];
259 excludes = ["**/src/_lex/**"];
260 };
261
262 # prettier = let
263 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
264 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
265 # '';
266 # in {
267 # command = wrapper;
268 # options = ["-w"];
269 # includes = ["*.html"];
270 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
271 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
272 # };
273 };
274 };
275
276 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
277 nixosSystem = self.nixosConfigurations.spindle-nixos;
278 };
279 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
280 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
281 '';
282
283 spindle-alpine-image = let
284 branch = "3.24";
285 version = "${branch}.0";
286 arch = "x86_64";
287 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
288
289 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
290 in
291 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
292 inherit arch shuttle;
293 repositories = [
294 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
295 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
296 ];
297 rootfs = linuxPkgs.fetchurl {
298 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
299 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
300 };
301 kernel = linuxPkgs.fetchurl {
302 url = "${cdn}/netboot-${version}/vmlinuz-virt";
303 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
304 };
305 initramfs = linuxPkgs.fetchurl {
306 url = "${cdn}/netboot-${version}/initramfs-virt";
307 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
308 };
309 modloop = linuxPkgs.fetchurl {
310 url = "${cdn}/netboot-${version}/modloop-virt";
311 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
312 };
313 };
314 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
315 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
316 '';
317 });
318 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
319 devShells = forAllSystems (system: let
320 pkgs = nixpkgsFor.${system};
321 packages' = self.packages.${system};
322 staticShell = args:
323 (pkgs.mkShell.override {
324 stdenv = pkgs.pkgsStatic.stdenv;
325 }) (args
326 // {
327 nativeBuildInputs =
328 args.nativeBuildInputs
329 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
330 pkgs.darwin.cctools
331 ];
332 });
333 in {
334 default = staticShell {
335 nativeBuildInputs =
336 [
337 pkgs.go
338 pkgs.air
339 pkgs.gopls
340 pkgs.httpie
341 pkgs.litecli
342 pkgs.websocat
343 pkgs.tailwindcss
344 pkgs.nixos-shell
345 pkgs.redis
346 pkgs.worker-build
347 pkgs.cargo-generate
348 pkgs.qemu
349 pkgs.cdrkit
350 pkgs.buf
351 pkgs.protobuf
352 pkgs.protoc-gen-prost
353 pkgs.protoc-gen-prost-crate
354 pkgs.protoc-gen-prost-serde
355 pkgs.protoc-gen-go
356 (fenix.packages.${system}.combine [
357 fenix.packages.${system}.stable.cargo
358 fenix.packages.${system}.stable.rustc
359 fenix.packages.${system}.stable.rust-src
360 fenix.packages.${system}.stable.clippy
361 fenix.packages.${system}.stable.rustfmt
362 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
363 ])
364 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
365 packages'.lexgen
366 packages'.treefmt-wrapper
367 packages'.tap
368 pkgs.e2fsprogs
369 pkgs.util-linux
370 ]
371 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
372 pkgs.parted
373 pkgs.slirp4netns
374 pkgs.iproute2
375 ];
376 shellHook = ''
377 export CC=${pkgs.stdenv.cc}/bin/cc
378 mkdir -p appview/pages/static
379 # temporary self-heal for workspaces that copied static assets as read-only
380 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
381 # no preserve is needed because watch-tailwind will want to be able to overwrite
382 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
383 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
384 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
385 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
386 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
387 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
388 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
389 fi
390 '';
391 env.CGO_ENABLED = 1;
392 };
393 });
394 apps = forAllSystems (system: let
395 pkgs = nixpkgsFor."${system}";
396 packages' = self.packages.${system};
397 air-watcher = name: arg:
398 pkgs.writeShellScriptBin "run"
399 ''
400 export PATH=${pkgs.go}/bin:$PATH
401 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
402 -build.args_bin "${arg}"
403 '';
404 tailwind-watcher =
405 pkgs.writeShellScriptBin "run"
406 ''
407 export BROWSERSLIST_IGNORE_OLD_DATA=true
408 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
409 '';
410 in {
411 watch-appview = {
412 type = "app";
413 program = toString (pkgs.writeShellScript "watch-appview" ''
414 echo "copying static files to appview/pages/static..."
415 mkdir -p appview/pages/static
416 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
417 ${air-watcher "appview" ""}/bin/run
418 '');
419 };
420 watch-knot = {
421 type = "app";
422 program = ''${air-watcher "knot" "server"}/bin/run'';
423 };
424 watch-spindle = {
425 type = "app";
426 program = ''${air-watcher "spindle" ""}/bin/run'';
427 };
428 watch-blog = {
429 type = "app";
430 program = toString (pkgs.writeShellScript "watch-blog" ''
431 echo "copying static files to appview/pages/static..."
432 mkdir -p appview/pages/static
433 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
434 ${air-watcher "blog" "serve"}/bin/run
435 '');
436 };
437 watch-tailwind = {
438 type = "app";
439 program = ''${tailwind-watcher}/bin/run'';
440 };
441 serve-docs = {
442 type = "app";
443 program = toString (pkgs.writeShellScript "serve-docs" ''
444 echo "building docs..."
445 docsOut=$(nix build --no-link --print-out-paths .#docs)
446 echo "serving docs at http://localhost:1414"
447 cd "$docsOut"
448 exec ${pkgs.python3}/bin/python3 -m http.server 1414
449 '');
450 };
451 regenerate-proto = {
452 type = "app";
453 program =
454 (pkgs.writeShellApplication {
455 name = "regenerate-proto";
456 runtimeInputs = with pkgs; [git buf coreutils];
457 text = ''
458 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
459 cd "$rootDir"
460 echo ">>> regenerating protobuf files.."
461 buf generate
462 echo ">>> generating file descriptor set for shuttle..."
463 buf build -o shuttle/src/gen/file_descriptor_set.bin
464 echo ">>> done"
465 '';
466 })
467 + "/bin/regenerate-proto";
468 };
469 vm = let
470 guestSystem =
471 if pkgs.stdenv.hostPlatform.isAarch64
472 then "aarch64-linux"
473 else "x86_64-linux";
474 in {
475 type = "app";
476 program =
477 (pkgs.writeShellApplication {
478 name = "launch-vm";
479 text = ''
480 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
481 cd "$rootDir"
482
483 # Reset TMPDIR in case it points to a stale nix-shell temp dir
484 export TMPDIR=/tmp
485
486 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
487
488 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
489 exec ${pkgs.lib.getExe
490 (import ./nix/vm.nix {
491 inherit nixpkgs self;
492 system = guestSystem;
493 hostSystem = system;
494 }).config.system.build.vm}
495 '';
496 })
497 + /bin/launch-vm;
498 };
499 gomod2nix = {
500 type = "app";
501 program = toString (pkgs.writeShellScript "gomod2nix" ''
502 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
503 '');
504 };
505 lexgen = {
506 type = "app";
507 program =
508 (pkgs.writeShellApplication {
509 name = "lexgen";
510 text = ''
511 if ! command -v lexgen > /dev/null; then
512 echo "error: must be executed from devshell"
513 exit 1
514 fi
515
516 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
517 cd "$rootDir"
518
519 # *_ext.go are hand-written extensions; never remove or mutate them
520 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
521 lexgen --build-file lexicon-build-config.json lexicons
522
523 # disable type registration temporarily while running cborgen
524 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
525 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
526 # lexgen generates incomplete Marshaler/Unmarshaler for union types
527 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -not -name "cbor_gen.go" -exec \
528 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
529 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
530 ${pkgs.gotools}/bin/goimports -w api/tangled/*
531 CGO_ENABLED=0 go run ./cmd/cborgen/
532 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
533
534 lexgen --build-file lexicon-build-config.json lexicons
535 rm api/tangled/*.bak
536 '';
537 })
538 + /bin/lexgen;
539 };
540 });
541
542 nixosModules.appview = {
543 lib,
544 pkgs,
545 ...
546 }: {
547 imports = [./nix/modules/appview.nix];
548
549 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
550 };
551 nixosModules.knotmirror = {
552 lib,
553 pkgs,
554 ...
555 }: {
556 imports = [./nix/modules/knotmirror.nix];
557
558 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
559 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
560 };
561 nixosModules.zoekt-tnglserver = {
562 lib,
563 pkgs,
564 ...
565 }: {
566 imports = [./nix/modules/zoekt-tnglserver.nix];
567
568 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
569 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
570 };
571 nixosModules.knot = {
572 lib,
573 pkgs,
574 ...
575 }: {
576 imports = [./nix/modules/knot.nix];
577
578 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
579 };
580 nixosModules.spindle = {
581 lib,
582 pkgs,
583 ...
584 }: {
585 imports = [./nix/modules/spindle.nix];
586
587 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
588 };
589 nixosModules.shuttle = {
590 lib,
591 pkgs,
592 ...
593 }: {
594 imports = [./nix/modules/shuttle.nix];
595
596 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
597 };
598
599 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
600
601 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
602
603 nixosConfigurations = let
604 spindleNixosBase = nixpkgs.lib.nixosSystem {
605 system = "x86_64-linux";
606 modules = [self.nixosModules.spindle-nixos];
607 };
608 in {
609 spindle-nixos = spindleNixosBase;
610 };
611 };
612}