kacaii.dev
This repository has no description
lustre
gleam
1mod client
2mod server
3mod shared
4
5set quiet := true
6
7pod_name := "pod_sigo"
8
9# List available recipes
10_default:
11 just --list
12
13# Build Lustre runtime and start HTTP server
14[group("dev")]
15dev: lint
16 just client::build
17 just server::run
18
19# Update project dependencies
20[group("dev")]
21deps-update:
22 just shared::_deps-update
23 just client::_deps-update
24 just server::_deps-update
25
26# Check for errors
27[group("dev")]
28lint: fmt
29 just server::_lint
30 just client::_lint
31 just shared::_lint
32
33# Run unit tests
34[group("dev")]
35test:
36 just client::_test
37 just server::_test
38
39# Format files
40[group("dev")]
41fmt:
42 just client::_fmt
43 just server::_fmt
44 just shared::_fmt
45
46# Starts the server and database
47[group("podman")]
48up: _create-pod
49 just server::init-database {{ pod_name }}
50 just server::init-server {{ pod_name }}
51 echo {{ GREEN }}"Listening on http://0.0.0.0:8000"{{ NORMAL }}
52
53# Starts only the database
54[group("podman")]
55db-up:
56 just _create-pod ""
57 just server::init-database {{ pod_name }}
58 echo {{ GREEN }}" PostgreSQL is ready on port 5432"{{ NORMAL }}
59
60# Stop and remove the entire pod
61[group("podman")]
62down:
63 podman pod exists {{ pod_name }} || (echo "Pod does not exist" && exit 1)
64 podman pod stop {{ pod_name }}
65 podman pod rm {{ pod_name }}
66
67# Create pod
68[group("podman")]
69_create-pod server_port="-p 8000:8000":
70 podman pod exists {{ pod_name }} \
71 || podman pod create --name {{ pod_name }} {{ server_port }} -p 5432:5432