mihaizaurus.at
forked from
tangled.org/core
Monorepo for Tangled
22 kB
619 lines
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://unpkg.com/htmx.org@2.0.4/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 # strange errors in console that i can't really make out
32 # url = "https://unpkg.com/htmx.org@2.0.4/dist/ext/ws.js";
33 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.2";
34 flake = false;
35 };
36 lucide-src = {
37 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
38 flake = false;
39 };
40 inter-fonts-src = {
41 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
42 flake = false;
43 };
44 actor-typeahead-src = {
45 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
46 flake = false;
47 };
48 mermaid-src = {
49 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
50 flake = false;
51 };
52 hls-src = {
53 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
54 flake = false;
55 };
56 mathjax-src = {
57 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
58 flake = false;
59 };
60 ibm-plex-mono-src = {
61 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
62 flake = false;
63 };
64 sqlite-lib-src = {
65 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
66 flake = false;
67 };
68 fetch-tangled = {
69 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
70 inputs.nixpkgs.follows = "nixpkgs";
71 };
72 };
73
74 outputs = {
75 self,
76 nixpkgs,
77 fenix,
78 gomod2nix,
79 indigo,
80 htmx-src,
81 htmx-ws-src,
82 lucide-src,
83 inter-fonts-src,
84 sqlite-lib-src,
85 ibm-plex-mono-src,
86 actor-typeahead-src,
87 mermaid-src,
88 hls-src,
89 microvm,
90 fetch-tangled,
91 mathjax-src,
92 ...
93 }: let
94 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
95 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
96 nixpkgsFor = forAllSystems (system:
97 import nixpkgs {
98 inherit system;
99 overlays = [fetch-tangled.overlays.default];
100 });
101
102 mkPackageSet = pkgs:
103 pkgs.lib.makeScope pkgs.newScope (self: {
104 src = let
105 fs = pkgs.lib.fileset;
106 in
107 fs.toSource {
108 root = ./.;
109 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
110 };
111 rustSrc = let
112 fs = pkgs.lib.fileset;
113 in
114 fs.toSource {
115 root = ./.;
116 fileset =
117 fs.intersection
118 (fs.fromSource self.src)
119 (fs.unions [
120 ./Cargo.toml
121 ./Cargo.lock
122 ./shuttle
123 ./bobbin
124 ]);
125 };
126 buildGoApplication =
127 (self.callPackage "${gomod2nix}/builder" {
128 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
129 }).buildGoApplication;
130 rustPlatform = pkgs.makeRustPlatform {
131 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
132 };
133 rustPlatformStatic = let
134 system = pkgs.stdenv.hostPlatform.system;
135 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
136 toolchain = fenix.packages.${system}.combine [
137 fenix.packages.${system}.stable.cargo
138 fenix.packages.${system}.stable.rustc
139 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
140 ];
141 in
142 pkgs.pkgsStatic.makeRustPlatform {
143 cargo = toolchain;
144 rustc = toolchain;
145 };
146 modules = ./nix/gomod2nix.toml;
147 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
148 inherit sqlite-lib-src;
149 };
150 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
151 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
152 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
153 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src;
154 };
155 appview = self.callPackage ./nix/pkgs/appview.nix {};
156 blog = self.callPackage ./nix/pkgs/blog.nix {};
157 docs = self.callPackage ./nix/pkgs/docs.nix {
158 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
159 inherit (pkgs) pagefind;
160 };
161 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
162 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
163 src = self.rustSrc;
164 };
165 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
166 src = self.rustSrc;
167 rustPlatform = self.rustPlatformStatic;
168 };
169 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
170 knot = self.callPackage ./nix/pkgs/knot.nix {};
171 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
172 tap = self.callPackage ./nix/pkgs/tap.nix {};
173 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
174 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
175 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
176 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
177 });
178 in {
179 overlays.default = final: prev: {
180 inherit
181 (mkPackageSet final)
182 lexgen
183 goat
184 sqlite-lib
185 spindle
186 shuttle
187 knot-unwrapped
188 knot
189 appview
190 docs
191 dolly
192 tap
193 knotmirror
194 bobbin
195 zoekt-webserver
196 zoekt-tngl-indexserver
197 ;
198 };
199
200 packages = forAllSystems (system: let
201 pkgs = nixpkgsFor.${system};
202 linuxPkgs = nixpkgsFor."x86_64-linux";
203 packages = mkPackageSet pkgs;
204 staticPackages = mkPackageSet pkgs.pkgsStatic;
205 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
206 in {
207 inherit
208 (packages)
209 appview
210 appview-static-files
211 blog
212 lexgen
213 goat
214 spindle
215 knot
216 knot-unwrapped
217 sqlite-lib
218 docs
219 shuttle
220 shuttle-static
221 dolly
222 tap
223 knotmirror
224 bobbin
225 zoekt-webserver
226 zoekt-tngl-indexserver
227 ;
228
229 pkgsStatic-appview = staticPackages.appview;
230 pkgsStatic-knot = staticPackages.knot;
231 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
232 pkgsStatic-spindle = staticPackages.spindle;
233 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
234 pkgsStatic-dolly = staticPackages.dolly;
235
236 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
237 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
238 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
239 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
240 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
241
242 treefmt-wrapper = pkgs.treefmt.withConfig {
243 settings.formatter = {
244 alejandra = {
245 command = pkgs.lib.getExe pkgs.alejandra;
246 includes = ["*.nix"];
247 };
248
249 gofmt = {
250 command = pkgs.lib.getExe' pkgs.go "gofmt";
251 options = ["-w"];
252 includes = ["*.go"];
253 };
254
255 rustfmt = {
256 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
257 options = ["--edition" "2024"];
258 includes = ["*.rs"];
259 excludes = ["**/src/_lex/**"];
260 };
261
262 # prettier = let
263 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
264 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
265 # '';
266 # in {
267 # command = wrapper;
268 # options = ["-w"];
269 # includes = ["*.html"];
270 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
271 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
272 # };
273 };
274 };
275
276 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
277 nixosSystem = self.nixosConfigurations.spindle-nixos;
278 };
279 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
280 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
281 '';
282
283 spindle-alpine-image = let
284 branch = "3.24";
285 version = "${branch}.0";
286 arch = "x86_64";
287 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
288
289 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
290 in
291 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
292 inherit arch shuttle;
293 repositories = [
294 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
295 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
296 ];
297 rootfs = linuxPkgs.fetchurl {
298 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
299 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
300 };
301 kernel = linuxPkgs.fetchurl {
302 url = "${cdn}/netboot-${version}/vmlinuz-virt";
303 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
304 };
305 initramfs = linuxPkgs.fetchurl {
306 url = "${cdn}/netboot-${version}/initramfs-virt";
307 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
308 };
309 modloop = linuxPkgs.fetchurl {
310 url = "${cdn}/netboot-${version}/modloop-virt";
311 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
312 };
313 };
314 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
315 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
316 '';
317 });
318 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
319 devShells = forAllSystems (system: let
320 pkgs = nixpkgsFor.${system};
321 packages' = self.packages.${system};
322 staticShell = args:
323 (pkgs.mkShell.override {
324 stdenv = pkgs.pkgsStatic.stdenv;
325 }) (args
326 // {
327 nativeBuildInputs =
328 args.nativeBuildInputs
329 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
330 pkgs.darwin.cctools
331 ];
332 }
333 // pkgs.lib.optionalAttrs pkgs.stdenv.isDarwin {
334 # Point cargo's linker at the nix cc-wrapper so NIX_LDFLAGS applies.
335 "CARGO_TARGET_${pkgs.lib.toUpper (builtins.replaceStrings ["-"] ["_"] pkgs.stdenv.hostPlatform.rust.rustcTarget)}_LINKER" = "${pkgs.pkgsStatic.stdenv.cc.targetPrefix}cc";
336 });
337 in {
338 default = staticShell {
339 nativeBuildInputs =
340 [
341 pkgs.go
342 pkgs.air
343 pkgs.gopls
344 pkgs.httpie
345 pkgs.litecli
346 pkgs.websocat
347 pkgs.tailwindcss
348 pkgs.nixos-shell
349 pkgs.redis
350 pkgs.worker-build
351 pkgs.cargo-generate
352 pkgs.qemu
353 pkgs.cdrkit
354 pkgs.buf
355 pkgs.protobuf
356 pkgs.protoc-gen-prost
357 pkgs.protoc-gen-prost-crate
358 pkgs.protoc-gen-prost-serde
359 pkgs.protoc-gen-go
360 pkgs.protoc-gen-go-grpc
361 (fenix.packages.${system}.combine [
362 fenix.packages.${system}.stable.cargo
363 fenix.packages.${system}.stable.rustc
364 fenix.packages.${system}.stable.rust-src
365 fenix.packages.${system}.stable.clippy
366 fenix.packages.${system}.stable.rustfmt
367 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
368 ])
369 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
370 packages'.lexgen
371 packages'.treefmt-wrapper
372 packages'.tap
373 pkgs.e2fsprogs
374 pkgs.util-linux
375 ]
376 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
377 pkgs.parted
378 pkgs.slirp4netns
379 pkgs.iproute2
380 ];
381 shellHook = ''
382 export CC=${pkgs.stdenv.cc}/bin/cc
383 mkdir -p appview/pages/static
384 # temporary self-heal for workspaces that copied static assets as read-only
385 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
386 # no preserve is needed because watch-tailwind will want to be able to overwrite
387 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
388 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
389 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
390 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
391 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
392 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
393 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
394 fi
395 '';
396 env.CGO_ENABLED = 1;
397 };
398 });
399 apps = forAllSystems (system: let
400 pkgs = nixpkgsFor."${system}";
401 packages' = self.packages.${system};
402 air-watcher = name: arg:
403 pkgs.writeShellScriptBin "run"
404 ''
405 export PATH=${pkgs.go}/bin:$PATH
406 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
407 -build.args_bin "${arg}"
408 '';
409 tailwind-watcher =
410 pkgs.writeShellScriptBin "run"
411 ''
412 export BROWSERSLIST_IGNORE_OLD_DATA=true
413 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
414 '';
415 in {
416 watch-appview = {
417 type = "app";
418 program = toString (pkgs.writeShellScript "watch-appview" ''
419 echo "copying static files to appview/pages/static..."
420 mkdir -p appview/pages/static
421 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
422 ${air-watcher "appview" ""}/bin/run
423 '');
424 };
425 watch-knot = {
426 type = "app";
427 program = ''${air-watcher "knot" "server"}/bin/run'';
428 };
429 watch-spindle = {
430 type = "app";
431 program = ''${air-watcher "spindle" ""}/bin/run'';
432 };
433 watch-blog = {
434 type = "app";
435 program = toString (pkgs.writeShellScript "watch-blog" ''
436 echo "copying static files to appview/pages/static..."
437 mkdir -p appview/pages/static
438 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
439 ${air-watcher "blog" "serve"}/bin/run
440 '');
441 };
442 watch-tailwind = {
443 type = "app";
444 program = ''${tailwind-watcher}/bin/run'';
445 };
446 serve-docs = {
447 type = "app";
448 program = toString (pkgs.writeShellScript "serve-docs" ''
449 echo "building docs..."
450 docsOut=$(nix build --no-link --print-out-paths .#docs)
451 echo "serving docs at http://localhost:1414"
452 cd "$docsOut"
453 exec ${pkgs.python3}/bin/python3 -m http.server 1414
454 '');
455 };
456 regenerate-proto = {
457 type = "app";
458 program =
459 (pkgs.writeShellApplication {
460 name = "regenerate-proto";
461 runtimeInputs = with pkgs; [git buf coreutils];
462 text = ''
463 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
464 cd "$rootDir"
465 echo ">>> regenerating protobuf files.."
466 buf generate
467 echo ">>> regenerating gitmirror go stubs..."
468 buf generate gitmirror --template gitmirror/buf.gen.yaml
469 echo ">>> generating file descriptor set for shuttle..."
470 buf build -o shuttle/src/gen/file_descriptor_set.bin
471 echo ">>> done"
472 '';
473 })
474 + "/bin/regenerate-proto";
475 };
476 vm = let
477 guestSystem =
478 if pkgs.stdenv.hostPlatform.isAarch64
479 then "aarch64-linux"
480 else "x86_64-linux";
481 in {
482 type = "app";
483 program =
484 (pkgs.writeShellApplication {
485 name = "launch-vm";
486 text = ''
487 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
488 cd "$rootDir"
489
490 # Reset TMPDIR in case it points to a stale nix-shell temp dir
491 export TMPDIR=/tmp
492
493 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
494
495 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
496 exec ${pkgs.lib.getExe
497 (import ./nix/vm.nix {
498 inherit nixpkgs self;
499 system = guestSystem;
500 hostSystem = system;
501 }).config.system.build.vm}
502 '';
503 })
504 + /bin/launch-vm;
505 };
506 gomod2nix = {
507 type = "app";
508 program = toString (pkgs.writeShellScript "gomod2nix" ''
509 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
510 '');
511 };
512 lexgen = {
513 type = "app";
514 program =
515 (pkgs.writeShellApplication {
516 name = "lexgen";
517 text = ''
518 if ! command -v lexgen > /dev/null; then
519 echo "error: must be executed from devshell"
520 exit 1
521 fi
522
523 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
524 cd "$rootDir"
525
526 # *_ext.go are hand-written extensions; never remove or mutate them
527 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
528 lexgen --build-file lexicon-build-config.json lexicons
529
530 # disable type registration temporarily while running cborgen
531 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
532 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
533 # lexgen generates incomplete Marshaler/Unmarshaler for union types
534 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -not -name "cbor_gen.go" -exec \
535 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
536 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
537 ${pkgs.gotools}/bin/goimports -w api/tangled/*
538 CGO_ENABLED=0 go run ./cmd/cborgen/
539 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
540
541 lexgen --build-file lexicon-build-config.json lexicons
542 rm api/tangled/*.bak
543 '';
544 })
545 + /bin/lexgen;
546 };
547 });
548
549 nixosModules.appview = {
550 lib,
551 pkgs,
552 ...
553 }: {
554 imports = [./nix/modules/appview.nix];
555
556 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
557 };
558 nixosModules.knotmirror = {
559 lib,
560 pkgs,
561 ...
562 }: {
563 imports = [./nix/modules/knotmirror.nix];
564
565 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
566 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
567 };
568 nixosModules.zoekt-tnglserver = {
569 lib,
570 pkgs,
571 ...
572 }: {
573 imports = [./nix/modules/zoekt-tnglserver.nix];
574
575 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
576 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
577 };
578 nixosModules.knot = {
579 lib,
580 pkgs,
581 ...
582 }: {
583 imports = [./nix/modules/knot.nix];
584
585 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
586 };
587 nixosModules.spindle = {
588 lib,
589 pkgs,
590 ...
591 }: {
592 imports = [./nix/modules/spindle.nix];
593
594 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
595 };
596 nixosModules.shuttle = {
597 lib,
598 pkgs,
599 ...
600 }: {
601 imports = [./nix/modules/shuttle.nix];
602
603 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
604 };
605
606 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
607
608 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
609
610 nixosConfigurations = let
611 spindleNixosBase = nixpkgs.lib.nixosSystem {
612 system = "x86_64-linux";
613 modules = [self.nixosModules.spindle-nixos];
614 };
615 in {
616 spindle-nixos = spindleNixosBase;
617 };
618 };
619}