paulvall.dev
forked from
tangled.org/core
Monorepo for Tangled
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://cdn.jsdelivr.net/npm/htmx.org@2.0.10/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.4";
32 flake = false;
33 };
34 lucide-src = {
35 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
36 flake = false;
37 };
38 inter-fonts-src = {
39 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
40 flake = false;
41 };
42 actor-typeahead-src = {
43 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
44 flake = false;
45 };
46 mermaid-src = {
47 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
48 flake = false;
49 };
50 hls-src = {
51 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
52 flake = false;
53 };
54 mathjax-src = {
55 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
56 flake = false;
57 };
58 tailwindcss-animated-src = {
59 url = "https://registry.npmjs.org/tailwindcss-animated/-/tailwindcss-animated-1.1.2.tgz";
60 flake = false;
61 };
62 ibm-plex-mono-src = {
63 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
64 flake = false;
65 };
66 sqlite-lib-src = {
67 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
68 flake = false;
69 };
70 fetch-tangled = {
71 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
72 inputs.nixpkgs.follows = "nixpkgs";
73 };
74 };
75
76 outputs = {
77 self,
78 nixpkgs,
79 fenix,
80 gomod2nix,
81 indigo,
82 htmx-src,
83 htmx-ws-src,
84 lucide-src,
85 inter-fonts-src,
86 sqlite-lib-src,
87 ibm-plex-mono-src,
88 actor-typeahead-src,
89 mermaid-src,
90 hls-src,
91 microvm,
92 fetch-tangled,
93 mathjax-src,
94 tailwindcss-animated-src,
95 ...
96 }: let
97 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
98 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
99 nixpkgsFor = forAllSystems (system:
100 import nixpkgs {
101 inherit system;
102 overlays = [fetch-tangled.overlays.default];
103 });
104
105 mkPackageSet = pkgs:
106 pkgs.lib.makeScope pkgs.newScope (self: {
107 src = let
108 fs = pkgs.lib.fileset;
109 in
110 fs.toSource {
111 root = ./.;
112 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
113 };
114 rustSrc = let
115 fs = pkgs.lib.fileset;
116 in
117 fs.toSource {
118 root = ./.;
119 fileset =
120 fs.intersection
121 (fs.fromSource self.src)
122 (fs.unions [
123 ./Cargo.toml
124 ./Cargo.lock
125 ./shuttle
126 ./bobbin
127 ]);
128 };
129 buildGoApplication =
130 (self.callPackage "${gomod2nix}/builder" {
131 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
132 }).buildGoApplication;
133 rustPlatform = pkgs.makeRustPlatform {
134 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
135 };
136 rustPlatformStatic = let
137 system = pkgs.stdenv.hostPlatform.system;
138 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
139 toolchain = fenix.packages.${system}.combine [
140 fenix.packages.${system}.stable.cargo
141 fenix.packages.${system}.stable.rustc
142 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
143 ];
144 in
145 pkgs.pkgsStatic.makeRustPlatform {
146 cargo = toolchain;
147 rustc = toolchain;
148 };
149 modules = ./nix/gomod2nix.toml;
150 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
151 inherit sqlite-lib-src;
152 };
153 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
154 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
155 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
156 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src tailwindcss-animated-src;
157 };
158 appview = self.callPackage ./nix/pkgs/appview.nix {};
159 blog = self.callPackage ./nix/pkgs/blog.nix {};
160 docs = self.callPackage ./nix/pkgs/docs.nix {
161 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
162 inherit (pkgs) pagefind;
163 };
164 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
165 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
166 src = self.rustSrc;
167 };
168 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
169 src = self.rustSrc;
170 rustPlatform = self.rustPlatformStatic;
171 };
172 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
173 knot = self.callPackage ./nix/pkgs/knot.nix {};
174 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
175 tap = self.callPackage ./nix/pkgs/tap.nix {};
176 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
177 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
178 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
179 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
180 });
181 in {
182 overlays.default = final: prev: {
183 inherit
184 (mkPackageSet final)
185 lexgen
186 goat
187 sqlite-lib
188 spindle
189 shuttle
190 knot-unwrapped
191 knot
192 appview
193 docs
194 dolly
195 tap
196 knotmirror
197 bobbin
198 zoekt-webserver
199 zoekt-tngl-indexserver
200 ;
201 };
202
203 packages = forAllSystems (system: let
204 pkgs = nixpkgsFor.${system};
205 linuxPkgs = nixpkgsFor."x86_64-linux";
206 packages = mkPackageSet pkgs;
207 staticPackages = mkPackageSet pkgs.pkgsStatic;
208 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
209 in {
210 inherit
211 (packages)
212 appview
213 appview-static-files
214 blog
215 lexgen
216 goat
217 spindle
218 knot
219 knot-unwrapped
220 sqlite-lib
221 docs
222 shuttle
223 shuttle-static
224 dolly
225 tap
226 knotmirror
227 bobbin
228 zoekt-webserver
229 zoekt-tngl-indexserver
230 ;
231
232 pkgsStatic-appview = staticPackages.appview;
233 pkgsStatic-knot = staticPackages.knot;
234 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
235 pkgsStatic-spindle = staticPackages.spindle;
236 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
237 pkgsStatic-dolly = staticPackages.dolly;
238
239 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
240 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
241 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
242 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
243 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
244
245 treefmt-wrapper = pkgs.treefmt.withConfig {
246 settings.formatter = {
247 alejandra = {
248 command = pkgs.lib.getExe pkgs.alejandra;
249 includes = ["*.nix"];
250 };
251
252 gofmt = {
253 command = pkgs.lib.getExe' pkgs.go "gofmt";
254 options = ["-w"];
255 includes = ["*.go"];
256 };
257
258 rustfmt = {
259 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
260 options = ["--edition" "2024"];
261 includes = ["*.rs"];
262 excludes = ["**/src/_lex/**"];
263 };
264
265 # prettier = let
266 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
267 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
268 # '';
269 # in {
270 # command = wrapper;
271 # options = ["-w"];
272 # includes = ["*.html"];
273 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
274 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
275 # };
276 };
277 };
278
279 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
280 nixosSystem = self.nixosConfigurations.spindle-nixos;
281 };
282 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
283 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
284 '';
285
286 spindle-alpine-image = let
287 branch = "3.24";
288 version = "${branch}.0";
289 arch = "x86_64";
290 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
291
292 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
293 in
294 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
295 inherit arch shuttle;
296 repositories = [
297 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
298 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
299 ];
300 rootfs = linuxPkgs.fetchurl {
301 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
302 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
303 };
304 kernel = linuxPkgs.fetchurl {
305 url = "${cdn}/netboot-${version}/vmlinuz-virt";
306 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
307 };
308 initramfs = linuxPkgs.fetchurl {
309 url = "${cdn}/netboot-${version}/initramfs-virt";
310 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
311 };
312 modloop = linuxPkgs.fetchurl {
313 url = "${cdn}/netboot-${version}/modloop-virt";
314 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
315 };
316 };
317 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
318 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
319 '';
320 });
321 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
322 devShells = forAllSystems (system: let
323 pkgs = nixpkgsFor.${system};
324 packages' = self.packages.${system};
325 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
326 {
327 name = "tailwindcss-animated";
328 path = tailwindcss-animated-src;
329 }
330 ];
331 staticShell = args:
332 (pkgs.mkShell.override {
333 stdenv = pkgs.pkgsStatic.stdenv;
334 }) (args
335 // {
336 nativeBuildInputs =
337 args.nativeBuildInputs
338 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
339 pkgs.darwin.cctools
340 ];
341 });
342 in {
343 default = staticShell {
344 nativeBuildInputs =
345 [
346 pkgs.go
347 pkgs.air
348 pkgs.gopls
349 pkgs.httpie
350 pkgs.litecli
351 pkgs.websocat
352 pkgs.tailwindcss
353 pkgs.nixos-shell
354 pkgs.redis
355 pkgs.worker-build
356 pkgs.cargo-generate
357 pkgs.qemu
358 pkgs.cdrkit
359 pkgs.buf
360 pkgs.protobuf
361 pkgs.protoc-gen-prost
362 pkgs.protoc-gen-prost-crate
363 pkgs.protoc-gen-prost-serde
364 pkgs.protoc-gen-go
365 (fenix.packages.${system}.combine [
366 fenix.packages.${system}.stable.cargo
367 fenix.packages.${system}.stable.rustc
368 fenix.packages.${system}.stable.rust-src
369 fenix.packages.${system}.stable.clippy
370 fenix.packages.${system}.stable.rustfmt
371 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
372 ])
373 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
374 packages'.lexgen
375 packages'.treefmt-wrapper
376 packages'.tap
377 pkgs.e2fsprogs
378 pkgs.util-linux
379 ]
380 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
381 pkgs.parted
382 pkgs.slirp4netns
383 pkgs.iproute2
384 ];
385 shellHook = ''
386 export CC=${pkgs.stdenv.cc}/bin/cc
387 export NODE_PATH=${tailwindcss-plugins}''${NODE_PATH:+:$NODE_PATH}
388 mkdir -p appview/pages/static
389 # temporary self-heal for workspaces that copied static assets as read-only
390 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
391 # no preserve is needed because watch-tailwind will want to be able to overwrite
392 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
393 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
394 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
395 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
396 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
397 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
398 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
399 fi
400 '';
401 env.CGO_ENABLED = 1;
402 };
403 });
404 apps = forAllSystems (system: let
405 pkgs = nixpkgsFor."${system}";
406 packages' = self.packages.${system};
407 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
408 {
409 name = "tailwindcss-animated";
410 path = tailwindcss-animated-src;
411 }
412 ];
413 air-watcher = name: arg:
414 pkgs.writeShellScriptBin "run"
415 ''
416 export PATH=${pkgs.go}/bin:$PATH
417 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
418 -build.args_bin "${arg}"
419 '';
420 tailwind-watcher =
421 pkgs.writeShellScriptBin "run"
422 ''
423 export BROWSERSLIST_IGNORE_OLD_DATA=true
424 export NODE_PATH=${tailwindcss-plugins}
425 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
426 '';
427 in {
428 watch-appview = {
429 type = "app";
430 program = toString (pkgs.writeShellScript "watch-appview" ''
431 echo "copying static files to appview/pages/static..."
432 mkdir -p appview/pages/static
433 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
434 ${air-watcher "appview" ""}/bin/run
435 '');
436 };
437 watch-knot = {
438 type = "app";
439 program = ''${air-watcher "knot" "server"}/bin/run'';
440 };
441 watch-spindle = {
442 type = "app";
443 program = ''${air-watcher "spindle" ""}/bin/run'';
444 };
445 watch-blog = {
446 type = "app";
447 program = toString (pkgs.writeShellScript "watch-blog" ''
448 echo "copying static files to appview/pages/static..."
449 mkdir -p appview/pages/static
450 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
451 ${air-watcher "blog" "serve"}/bin/run
452 '');
453 };
454 watch-tailwind = {
455 type = "app";
456 program = ''${tailwind-watcher}/bin/run'';
457 };
458 serve-docs = {
459 type = "app";
460 program = toString (pkgs.writeShellScript "serve-docs" ''
461 echo "building docs..."
462 docsOut=$(nix build --no-link --print-out-paths .#docs)
463 echo "serving docs at http://localhost:1414"
464 cd "$docsOut"
465 exec ${pkgs.python3}/bin/python3 -m http.server 1414
466 '');
467 };
468 regenerate-proto = {
469 type = "app";
470 program =
471 (pkgs.writeShellApplication {
472 name = "regenerate-proto";
473 runtimeInputs = with pkgs; [git buf coreutils];
474 text = ''
475 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
476 cd "$rootDir"
477 echo ">>> regenerating protobuf files.."
478 buf generate
479 echo ">>> generating file descriptor set for shuttle..."
480 buf build -o shuttle/src/gen/file_descriptor_set.bin
481 echo ">>> done"
482 '';
483 })
484 + "/bin/regenerate-proto";
485 };
486 vm = let
487 guestSystem =
488 if pkgs.stdenv.hostPlatform.isAarch64
489 then "aarch64-linux"
490 else "x86_64-linux";
491 in {
492 type = "app";
493 program =
494 (pkgs.writeShellApplication {
495 name = "launch-vm";
496 text = ''
497 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
498 cd "$rootDir"
499
500 # Reset TMPDIR in case it points to a stale nix-shell temp dir
501 export TMPDIR=/tmp
502
503 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
504
505 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
506 exec ${pkgs.lib.getExe
507 (import ./nix/vm.nix {
508 inherit nixpkgs self;
509 system = guestSystem;
510 hostSystem = system;
511 }).config.system.build.vm}
512 '';
513 })
514 + /bin/launch-vm;
515 };
516 gomod2nix = {
517 type = "app";
518 program = toString (pkgs.writeShellScript "gomod2nix" ''
519 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
520 '');
521 };
522 lexgen = {
523 type = "app";
524 program =
525 (pkgs.writeShellApplication {
526 name = "lexgen";
527 text = ''
528 if ! command -v lexgen > /dev/null; then
529 echo "error: must be executed from devshell"
530 exit 1
531 fi
532
533 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
534 cd "$rootDir"
535
536 # *_ext.go are hand-written extensions; never remove or mutate them
537 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
538 lexgen --build-file lexicon-build-config.json lexicons
539
540 # disable type registration temporarily while running cborgen
541 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
542 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
543 # lexgen generates incomplete Marshaler/Unmarshaler for union types
544 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -not -name "cbor_gen.go" -exec \
545 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
546 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
547 ${pkgs.gotools}/bin/goimports -w api/tangled/*
548 CGO_ENABLED=0 go run ./cmd/cborgen/
549 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
550
551 lexgen --build-file lexicon-build-config.json lexicons
552 rm api/tangled/*.bak
553 '';
554 })
555 + /bin/lexgen;
556 };
557 });
558
559 nixosModules.appview = {
560 lib,
561 pkgs,
562 ...
563 }: {
564 imports = [./nix/modules/appview.nix];
565
566 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
567 };
568 nixosModules.knotmirror = {
569 lib,
570 pkgs,
571 ...
572 }: {
573 imports = [./nix/modules/knotmirror.nix];
574
575 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
576 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
577 };
578 nixosModules.zoekt-tnglserver = {
579 lib,
580 pkgs,
581 ...
582 }: {
583 imports = [./nix/modules/zoekt-tnglserver.nix];
584
585 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
586 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
587 };
588 nixosModules.knot = {
589 lib,
590 pkgs,
591 ...
592 }: {
593 imports = [./nix/modules/knot.nix];
594
595 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
596 };
597 nixosModules.spindle = {
598 lib,
599 pkgs,
600 ...
601 }: {
602 imports = [./nix/modules/spindle.nix];
603
604 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
605 };
606 nixosModules.shuttle = {
607 lib,
608 pkgs,
609 ...
610 }: {
611 imports = [./nix/modules/shuttle.nix];
612
613 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
614 };
615
616 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
617
618 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
619
620 nixosConfigurations = let
621 spindleNixosBase = nixpkgs.lib.nixosSystem {
622 system = "x86_64-linux";
623 modules = [self.nixosModules.spindle-nixos];
624 };
625 in {
626 spindle-nixos = spindleNixosBase;
627 };
628 };
629}