tangled.org
Monorepo for Tangled
tangled.org
23 kB
637 lines
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://cdn.jsdelivr.net/npm/htmx.org@2.0.10/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.4";
32 flake = false;
33 };
34 lucide-src = {
35 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
36 flake = false;
37 };
38 inter-fonts-src = {
39 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
40 flake = false;
41 };
42 actor-typeahead-src = {
43 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
44 flake = false;
45 };
46 mermaid-src = {
47 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
48 flake = false;
49 };
50 hls-src = {
51 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
52 flake = false;
53 };
54 mathjax-src = {
55 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
56 flake = false;
57 };
58 tailwindcss-animated-src = {
59 url = "https://registry.npmjs.org/tailwindcss-animated/-/tailwindcss-animated-1.1.2.tgz";
60 flake = false;
61 };
62 ibm-plex-mono-src = {
63 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
64 flake = false;
65 };
66 sqlite-lib-src = {
67 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
68 flake = false;
69 };
70 fetch-tangled = {
71 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
72 inputs.nixpkgs.follows = "nixpkgs";
73 };
74 };
75
76 outputs = {
77 self,
78 nixpkgs,
79 fenix,
80 gomod2nix,
81 indigo,
82 htmx-src,
83 htmx-ws-src,
84 lucide-src,
85 inter-fonts-src,
86 sqlite-lib-src,
87 ibm-plex-mono-src,
88 actor-typeahead-src,
89 mermaid-src,
90 hls-src,
91 microvm,
92 fetch-tangled,
93 mathjax-src,
94 tailwindcss-animated-src,
95 ...
96 }: let
97 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
98 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
99 nixpkgsFor = forAllSystems (system:
100 import nixpkgs {
101 inherit system;
102 overlays = [fetch-tangled.overlays.default];
103 });
104
105 mkPackageSet = pkgs:
106 pkgs.lib.makeScope pkgs.newScope (self: {
107 src = let
108 fs = pkgs.lib.fileset;
109 in
110 fs.toSource {
111 root = ./.;
112 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
113 };
114 rustSrc = let
115 fs = pkgs.lib.fileset;
116 in
117 fs.toSource {
118 root = ./.;
119 fileset =
120 fs.intersection
121 (fs.fromSource self.src)
122 (fs.unions [
123 ./Cargo.toml
124 ./Cargo.lock
125 ./shuttle
126 ./bobbin
127 ]);
128 };
129 buildGoApplication =
130 (self.callPackage "${gomod2nix}/builder" {
131 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
132 }).buildGoApplication;
133 rustPlatform = pkgs.makeRustPlatform {
134 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
135 };
136 rustPlatformStatic = let
137 system = pkgs.stdenv.hostPlatform.system;
138 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
139 toolchain = fenix.packages.${system}.combine [
140 fenix.packages.${system}.stable.cargo
141 fenix.packages.${system}.stable.rustc
142 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
143 ];
144 in
145 pkgs.pkgsStatic.makeRustPlatform {
146 cargo = toolchain;
147 rustc = toolchain;
148 };
149 modules = ./nix/gomod2nix.toml;
150 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
151 inherit sqlite-lib-src;
152 };
153 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
154 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
155 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
156 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src tailwindcss-animated-src;
157 };
158 web-static-files = self.callPackage ./nix/pkgs/web-static-files.nix {
159 inherit inter-fonts-src ibm-plex-mono-src;
160 };
161 appview = self.callPackage ./nix/pkgs/appview.nix {};
162 blog = self.callPackage ./nix/pkgs/blog.nix {};
163 docs = self.callPackage ./nix/pkgs/docs.nix {
164 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
165 inherit (pkgs) pagefind;
166 };
167 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
168 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
169 src = self.rustSrc;
170 };
171 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
172 src = self.rustSrc;
173 rustPlatform = self.rustPlatformStatic;
174 };
175 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
176 knot = self.callPackage ./nix/pkgs/knot.nix {};
177 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
178 tap = self.callPackage ./nix/pkgs/tap.nix {};
179 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
180 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
181 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
182 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
183 });
184 in {
185 overlays.default = final: prev: {
186 inherit
187 (mkPackageSet final)
188 lexgen
189 goat
190 sqlite-lib
191 spindle
192 shuttle
193 knot-unwrapped
194 knot
195 appview
196 docs
197 dolly
198 tap
199 knotmirror
200 bobbin
201 zoekt-webserver
202 zoekt-tngl-indexserver
203 ;
204 };
205
206 packages = forAllSystems (system: let
207 pkgs = nixpkgsFor.${system};
208 linuxPkgs = nixpkgsFor."x86_64-linux";
209 packages = mkPackageSet pkgs;
210 staticPackages = mkPackageSet pkgs.pkgsStatic;
211 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
212 in {
213 inherit
214 (packages)
215 appview
216 appview-static-files
217 web-static-files
218 blog
219 lexgen
220 goat
221 spindle
222 knot
223 knot-unwrapped
224 sqlite-lib
225 docs
226 shuttle
227 shuttle-static
228 dolly
229 tap
230 knotmirror
231 bobbin
232 zoekt-webserver
233 zoekt-tngl-indexserver
234 ;
235
236 pkgsStatic-appview = staticPackages.appview;
237 pkgsStatic-knot = staticPackages.knot;
238 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
239 pkgsStatic-spindle = staticPackages.spindle;
240 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
241 pkgsStatic-dolly = staticPackages.dolly;
242
243 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
244 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
245 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
246 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
247 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
248
249 treefmt-wrapper = pkgs.treefmt.withConfig {
250 settings.formatter = {
251 alejandra = {
252 command = pkgs.lib.getExe pkgs.alejandra;
253 includes = ["*.nix"];
254 };
255
256 gofmt = {
257 command = pkgs.lib.getExe' pkgs.go "gofmt";
258 options = ["-w"];
259 includes = ["*.go"];
260 };
261
262 rustfmt = {
263 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
264 options = ["--edition" "2024"];
265 includes = ["*.rs"];
266 excludes = ["**/src/_lex/**"];
267 };
268
269 # prettier = let
270 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
271 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
272 # '';
273 # in {
274 # command = wrapper;
275 # options = ["-w"];
276 # includes = ["*.html"];
277 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
278 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
279 # };
280 };
281 };
282
283 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
284 nixosSystem = self.nixosConfigurations.spindle-nixos;
285 };
286 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
287 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
288 '';
289
290 spindle-alpine-image = let
291 branch = "3.24";
292 version = "${branch}.0";
293 arch = "x86_64";
294 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
295
296 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
297 in
298 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
299 inherit arch shuttle;
300 repositories = [
301 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
302 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
303 ];
304 rootfs = linuxPkgs.fetchurl {
305 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
306 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
307 };
308 kernel = linuxPkgs.fetchurl {
309 url = "${cdn}/netboot-${version}/vmlinuz-virt";
310 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
311 };
312 initramfs = linuxPkgs.fetchurl {
313 url = "${cdn}/netboot-${version}/initramfs-virt";
314 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
315 };
316 modloop = linuxPkgs.fetchurl {
317 url = "${cdn}/netboot-${version}/modloop-virt";
318 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
319 };
320 };
321 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
322 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
323 '';
324 });
325 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
326 devShells = forAllSystems (system: let
327 pkgs = nixpkgsFor.${system};
328 packages' = self.packages.${system};
329 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
330 {
331 name = "tailwindcss-animated";
332 path = tailwindcss-animated-src;
333 }
334 ];
335 staticShell = args:
336 (pkgs.mkShell.override {
337 stdenv = pkgs.pkgsStatic.stdenv;
338 }) (args
339 // {
340 nativeBuildInputs =
341 args.nativeBuildInputs
342 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
343 pkgs.darwin.cctools
344 ];
345 });
346 in {
347 default = staticShell {
348 nativeBuildInputs =
349 [
350 pkgs.go
351 pkgs.air
352 pkgs.gopls
353 pkgs.httpie
354 pkgs.litecli
355 pkgs.websocat
356 pkgs.tailwindcss
357 pkgs.nixos-shell
358 pkgs.redis
359 pkgs.worker-build
360 pkgs.cargo-generate
361 pkgs.qemu
362 pkgs.cdrkit
363 pkgs.buf
364 pkgs.protobuf
365 pkgs.protoc-gen-prost
366 pkgs.protoc-gen-prost-crate
367 pkgs.protoc-gen-prost-serde
368 pkgs.protoc-gen-go
369 (fenix.packages.${system}.combine [
370 fenix.packages.${system}.stable.cargo
371 fenix.packages.${system}.stable.rustc
372 fenix.packages.${system}.stable.rust-src
373 fenix.packages.${system}.stable.clippy
374 fenix.packages.${system}.stable.rustfmt
375 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
376 ])
377 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
378 packages'.lexgen
379 packages'.treefmt-wrapper
380 packages'.tap
381 pkgs.e2fsprogs
382 pkgs.util-linux
383 pkgs.pnpm
384 ]
385 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
386 pkgs.parted
387 pkgs.slirp4netns
388 pkgs.iproute2
389 ];
390 shellHook = ''
391 export CC=${pkgs.stdenv.cc}/bin/cc
392 export NODE_PATH=${tailwindcss-plugins}''${NODE_PATH:+:$NODE_PATH}
393 mkdir -p appview/pages/static
394 # temporary self-heal for workspaces that copied static assets as read-only
395 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
396 # no preserve is needed because watch-tailwind will want to be able to overwrite
397 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
398 mkdir -p web/static
399 rm -rf web/static/fonts web/static/logos
400 cp -fr --no-preserve=ownership,mode ${packages'.web-static-files}/* web/static
401 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
402 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
403 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
404 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
405 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
406 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
407 fi
408 '';
409 env.CGO_ENABLED = 1;
410 };
411 });
412 apps = forAllSystems (system: let
413 pkgs = nixpkgsFor."${system}";
414 packages' = self.packages.${system};
415 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
416 {
417 name = "tailwindcss-animated";
418 path = tailwindcss-animated-src;
419 }
420 ];
421 air-watcher = name: arg:
422 pkgs.writeShellScriptBin "run"
423 ''
424 export PATH=${pkgs.go}/bin:$PATH
425 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
426 -build.args_bin "${arg}"
427 '';
428 tailwind-watcher =
429 pkgs.writeShellScriptBin "run"
430 ''
431 export BROWSERSLIST_IGNORE_OLD_DATA=true
432 export NODE_PATH=${tailwindcss-plugins}
433 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
434 '';
435 in {
436 watch-appview = {
437 type = "app";
438 program = toString (pkgs.writeShellScript "watch-appview" ''
439 echo "copying static files to appview/pages/static..."
440 mkdir -p appview/pages/static
441 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
442 ${air-watcher "appview" ""}/bin/run
443 '');
444 };
445 watch-knot = {
446 type = "app";
447 program = ''${air-watcher "knot" "server"}/bin/run'';
448 };
449 watch-spindle = {
450 type = "app";
451 program = ''${air-watcher "spindle" ""}/bin/run'';
452 };
453 watch-blog = {
454 type = "app";
455 program = toString (pkgs.writeShellScript "watch-blog" ''
456 echo "copying static files to appview/pages/static..."
457 mkdir -p appview/pages/static
458 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
459 ${air-watcher "blog" "serve"}/bin/run
460 '');
461 };
462 watch-tailwind = {
463 type = "app";
464 program = ''${tailwind-watcher}/bin/run'';
465 };
466 serve-docs = {
467 type = "app";
468 program = toString (pkgs.writeShellScript "serve-docs" ''
469 echo "building docs..."
470 docsOut=$(nix build --no-link --print-out-paths .#docs)
471 echo "serving docs at http://localhost:1414"
472 cd "$docsOut"
473 exec ${pkgs.python3}/bin/python3 -m http.server 1414
474 '');
475 };
476 regenerate-proto = {
477 type = "app";
478 program =
479 (pkgs.writeShellApplication {
480 name = "regenerate-proto";
481 runtimeInputs = with pkgs; [git buf coreutils];
482 text = ''
483 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
484 cd "$rootDir"
485 echo ">>> regenerating protobuf files.."
486 buf generate
487 echo ">>> generating file descriptor set for shuttle..."
488 buf build -o shuttle/src/gen/file_descriptor_set.bin
489 echo ">>> done"
490 '';
491 })
492 + "/bin/regenerate-proto";
493 };
494 vm = let
495 guestSystem =
496 if pkgs.stdenv.hostPlatform.isAarch64
497 then "aarch64-linux"
498 else "x86_64-linux";
499 in {
500 type = "app";
501 program =
502 (pkgs.writeShellApplication {
503 name = "launch-vm";
504 text = ''
505 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
506 cd "$rootDir"
507
508 # Reset TMPDIR in case it points to a stale nix-shell temp dir
509 export TMPDIR=/tmp
510
511 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
512
513 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
514 exec ${pkgs.lib.getExe
515 (import ./nix/vm.nix {
516 inherit nixpkgs self;
517 system = guestSystem;
518 hostSystem = system;
519 }).config.system.build.vm}
520 '';
521 })
522 + /bin/launch-vm;
523 };
524 gomod2nix = {
525 type = "app";
526 program = toString (pkgs.writeShellScript "gomod2nix" ''
527 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
528 '');
529 };
530 lexgen = {
531 type = "app";
532 program =
533 (pkgs.writeShellApplication {
534 name = "lexgen";
535 text = ''
536 if ! command -v lexgen > /dev/null; then
537 echo "error: must be executed from devshell"
538 exit 1
539 fi
540
541 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
542 cd "$rootDir"
543
544 # *_ext.go are hand-written extensions; never remove or mutate them
545 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
546 lexgen --build-file lexicon-build-config.json lexicons
547
548 # disable type registration temporarily while running cborgen
549 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
550 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
551 # lexgen generates incomplete Marshaler/Unmarshaler for union types
552 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -not -name "cbor_gen.go" -exec \
553 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
554 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
555 ${pkgs.gotools}/bin/goimports -w api/tangled/*
556 CGO_ENABLED=0 go run ./cmd/cborgen/
557 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
558
559 lexgen --build-file lexicon-build-config.json lexicons
560 rm api/tangled/*.bak
561 '';
562 })
563 + /bin/lexgen;
564 };
565 });
566
567 nixosModules.appview = {
568 lib,
569 pkgs,
570 ...
571 }: {
572 imports = [./nix/modules/appview.nix];
573
574 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
575 };
576 nixosModules.knotmirror = {
577 lib,
578 pkgs,
579 ...
580 }: {
581 imports = [./nix/modules/knotmirror.nix];
582
583 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
584 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
585 };
586 nixosModules.zoekt-tnglserver = {
587 lib,
588 pkgs,
589 ...
590 }: {
591 imports = [./nix/modules/zoekt-tnglserver.nix];
592
593 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
594 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
595 };
596 nixosModules.knot = {
597 lib,
598 pkgs,
599 ...
600 }: {
601 imports = [./nix/modules/knot.nix];
602
603 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
604 };
605 nixosModules.spindle = {
606 lib,
607 pkgs,
608 ...
609 }: {
610 imports = [./nix/modules/spindle.nix];
611
612 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
613 };
614 nixosModules.shuttle = {
615 lib,
616 pkgs,
617 ...
618 }: {
619 imports = [./nix/modules/shuttle.nix];
620
621 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
622 };
623
624 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
625
626 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
627
628 nixosConfigurations = let
629 spindleNixosBase = nixpkgs.lib.nixosSystem {
630 system = "x86_64-linux";
631 modules = [self.nixosModules.spindle-nixos];
632 };
633 in {
634 spindle-nixos = spindleNixosBase;
635 };
636 };
637}