tangled.org
Monorepo for Tangled
tangled.org
23 kB
639 lines
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://cdn.jsdelivr.net/npm/htmx.org@2.0.10/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.4";
32 flake = false;
33 };
34 lucide-src = {
35 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
36 flake = false;
37 };
38 inter-fonts-src = {
39 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
40 flake = false;
41 };
42 actor-typeahead-src = {
43 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
44 flake = false;
45 };
46 mermaid-src = {
47 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
48 flake = false;
49 };
50 hls-src = {
51 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
52 flake = false;
53 };
54 mathjax-src = {
55 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
56 flake = false;
57 };
58 tailwindcss-animated-src = {
59 url = "https://registry.npmjs.org/tailwindcss-animated/-/tailwindcss-animated-1.1.2.tgz";
60 flake = false;
61 };
62 ibm-plex-mono-src = {
63 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
64 flake = false;
65 };
66 sqlite-lib-src = {
67 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
68 flake = false;
69 };
70 fetch-tangled = {
71 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
72 inputs.nixpkgs.follows = "nixpkgs";
73 };
74 };
75
76 outputs = {
77 self,
78 nixpkgs,
79 fenix,
80 gomod2nix,
81 indigo,
82 htmx-src,
83 htmx-ws-src,
84 lucide-src,
85 inter-fonts-src,
86 sqlite-lib-src,
87 ibm-plex-mono-src,
88 actor-typeahead-src,
89 mermaid-src,
90 hls-src,
91 microvm,
92 fetch-tangled,
93 mathjax-src,
94 tailwindcss-animated-src,
95 ...
96 }: let
97 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
98 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
99 nixpkgsFor = forAllSystems (system:
100 import nixpkgs {
101 inherit system;
102 overlays = [fetch-tangled.overlays.default];
103 });
104
105 mkPackageSet = pkgs:
106 pkgs.lib.makeScope pkgs.newScope (self: {
107 src = let
108 fs = pkgs.lib.fileset;
109 in
110 fs.toSource {
111 root = ./.;
112 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
113 };
114 rustSrc = let
115 fs = pkgs.lib.fileset;
116 in
117 fs.toSource {
118 root = ./.;
119 fileset =
120 fs.intersection
121 (fs.fromSource self.src)
122 (fs.unions [
123 ./Cargo.toml
124 ./Cargo.lock
125 ./lexicons
126 ./shuttle
127 ./bobbin
128 ./knot2
129 ]);
130 };
131 buildGoApplication =
132 (self.callPackage "${gomod2nix}/builder" {
133 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
134 }).buildGoApplication;
135 rustPlatform = pkgs.makeRustPlatform {
136 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
137 };
138 rustPlatformStatic = let
139 system = pkgs.stdenv.hostPlatform.system;
140 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
141 toolchain = fenix.packages.${system}.combine [
142 fenix.packages.${system}.stable.cargo
143 fenix.packages.${system}.stable.rustc
144 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
145 ];
146 in
147 pkgs.pkgsStatic.makeRustPlatform {
148 cargo = toolchain;
149 rustc = toolchain;
150 };
151 modules = ./nix/gomod2nix.toml;
152 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
153 inherit sqlite-lib-src;
154 };
155 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
156 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
157 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
158 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src tailwindcss-animated-src;
159 };
160 web-static-files = self.callPackage ./nix/pkgs/web-static-files.nix {
161 inherit inter-fonts-src ibm-plex-mono-src;
162 };
163 appview = self.callPackage ./nix/pkgs/appview.nix {};
164 blog = self.callPackage ./nix/pkgs/blog.nix {};
165 docs = self.callPackage ./nix/pkgs/docs.nix {
166 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
167 inherit (pkgs) pagefind;
168 };
169 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
170 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
171 src = self.rustSrc;
172 };
173 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
174 src = self.rustSrc;
175 rustPlatform = self.rustPlatformStatic;
176 };
177 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
178 knot = self.callPackage ./nix/pkgs/knot.nix {};
179 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
180 tap = self.callPackage ./nix/pkgs/tap.nix {};
181 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
182 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
183 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
184 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
185 });
186 in {
187 overlays.default = final: prev: {
188 inherit
189 (mkPackageSet final)
190 lexgen
191 goat
192 sqlite-lib
193 spindle
194 shuttle
195 knot-unwrapped
196 knot
197 appview
198 docs
199 dolly
200 tap
201 knotmirror
202 bobbin
203 zoekt-webserver
204 zoekt-tngl-indexserver
205 ;
206 };
207
208 packages = forAllSystems (system: let
209 pkgs = nixpkgsFor.${system};
210 linuxPkgs = nixpkgsFor."x86_64-linux";
211 packages = mkPackageSet pkgs;
212 staticPackages = mkPackageSet pkgs.pkgsStatic;
213 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
214 in {
215 inherit
216 (packages)
217 appview
218 appview-static-files
219 web-static-files
220 blog
221 lexgen
222 goat
223 spindle
224 knot
225 knot-unwrapped
226 sqlite-lib
227 docs
228 shuttle
229 shuttle-static
230 dolly
231 tap
232 knotmirror
233 bobbin
234 zoekt-webserver
235 zoekt-tngl-indexserver
236 ;
237
238 pkgsStatic-appview = staticPackages.appview;
239 pkgsStatic-knot = staticPackages.knot;
240 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
241 pkgsStatic-spindle = staticPackages.spindle;
242 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
243 pkgsStatic-dolly = staticPackages.dolly;
244
245 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
246 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
247 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
248 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
249 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
250
251 treefmt-wrapper = pkgs.treefmt.withConfig {
252 settings.formatter = {
253 alejandra = {
254 command = pkgs.lib.getExe pkgs.alejandra;
255 includes = ["*.nix"];
256 };
257
258 gofmt = {
259 command = pkgs.lib.getExe' pkgs.go "gofmt";
260 options = ["-w"];
261 includes = ["*.go"];
262 };
263
264 rustfmt = {
265 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
266 options = ["--edition" "2024"];
267 includes = ["*.rs"];
268 excludes = ["**/src/_lex/**"];
269 };
270
271 # prettier = let
272 # wrapper = pkgs.runCommandLocal "prettier-wrapper" {nativeBuildInputs = [pkgs.makeWrapper];} ''
273 # makeWrapper ${pkgs.prettier}/bin/prettier "$out" --add-flags "--plugin=${pkgs.prettier-plugin-go-template}/lib/node_modules/prettier-plugin-go-template/lib/index.js"
274 # '';
275 # in {
276 # command = wrapper;
277 # options = ["-w"];
278 # includes = ["*.html"];
279 # # causes Go template plugin errors: https://github.com/NiklasPor/prettier-plugin-go-template/issues/120
280 # excludes = ["appview/pages/templates/layouts/repobase.html" "appview/pages/templates/repo/tags.html"];
281 # };
282 };
283 };
284
285 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
286 nixosSystem = self.nixosConfigurations.spindle-nixos;
287 };
288 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
289 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
290 '';
291
292 spindle-alpine-image = let
293 branch = "3.24";
294 version = "${branch}.0";
295 arch = "x86_64";
296 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
297
298 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
299 in
300 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
301 inherit arch shuttle;
302 repositories = [
303 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
304 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
305 ];
306 rootfs = linuxPkgs.fetchurl {
307 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
308 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
309 };
310 kernel = linuxPkgs.fetchurl {
311 url = "${cdn}/netboot-${version}/vmlinuz-virt";
312 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
313 };
314 initramfs = linuxPkgs.fetchurl {
315 url = "${cdn}/netboot-${version}/initramfs-virt";
316 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
317 };
318 modloop = linuxPkgs.fetchurl {
319 url = "${cdn}/netboot-${version}/modloop-virt";
320 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
321 };
322 };
323 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
324 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
325 '';
326 });
327 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
328 devShells = forAllSystems (system: let
329 pkgs = nixpkgsFor.${system};
330 packages' = self.packages.${system};
331 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
332 {
333 name = "tailwindcss-animated";
334 path = tailwindcss-animated-src;
335 }
336 ];
337 staticShell = args:
338 (pkgs.mkShell.override {
339 stdenv = pkgs.pkgsStatic.stdenv;
340 }) (args
341 // {
342 nativeBuildInputs =
343 args.nativeBuildInputs
344 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
345 pkgs.darwin.cctools
346 ];
347 });
348 in {
349 default = staticShell {
350 nativeBuildInputs =
351 [
352 pkgs.go
353 pkgs.air
354 pkgs.gopls
355 pkgs.httpie
356 pkgs.litecli
357 pkgs.websocat
358 pkgs.tailwindcss
359 pkgs.nixos-shell
360 pkgs.redis
361 pkgs.worker-build
362 pkgs.cargo-generate
363 pkgs.qemu
364 pkgs.cdrkit
365 pkgs.buf
366 pkgs.protobuf
367 pkgs.protoc-gen-prost
368 pkgs.protoc-gen-prost-crate
369 pkgs.protoc-gen-prost-serde
370 pkgs.protoc-gen-go
371 (fenix.packages.${system}.combine [
372 fenix.packages.${system}.stable.cargo
373 fenix.packages.${system}.stable.rustc
374 fenix.packages.${system}.stable.rust-src
375 fenix.packages.${system}.stable.clippy
376 fenix.packages.${system}.stable.rustfmt
377 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
378 ])
379 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
380 packages'.lexgen
381 packages'.treefmt-wrapper
382 packages'.tap
383 pkgs.e2fsprogs
384 pkgs.util-linux
385 pkgs.pnpm
386 ]
387 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
388 pkgs.parted
389 pkgs.slirp4netns
390 pkgs.iproute2
391 ];
392 shellHook = ''
393 export CC=${pkgs.stdenv.cc}/bin/cc
394 export NODE_PATH=${tailwindcss-plugins}''${NODE_PATH:+:$NODE_PATH}
395 mkdir -p appview/pages/static
396 # temporary self-heal for workspaces that copied static assets as read-only
397 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
398 # no preserve is needed because watch-tailwind will want to be able to overwrite
399 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
400 mkdir -p web/static
401 rm -rf web/static/fonts web/static/logos
402 cp -fr --no-preserve=ownership,mode ${packages'.web-static-files}/* web/static
403 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
404 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
405 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
406 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
407 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
408 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
409 fi
410 '';
411 env.CGO_ENABLED = 1;
412 };
413 });
414 apps = forAllSystems (system: let
415 pkgs = nixpkgsFor."${system}";
416 packages' = self.packages.${system};
417 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
418 {
419 name = "tailwindcss-animated";
420 path = tailwindcss-animated-src;
421 }
422 ];
423 air-watcher = name: arg:
424 pkgs.writeShellScriptBin "run"
425 ''
426 export PATH=${pkgs.go}/bin:$PATH
427 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
428 -build.args_bin "${arg}"
429 '';
430 tailwind-watcher =
431 pkgs.writeShellScriptBin "run"
432 ''
433 export BROWSERSLIST_IGNORE_OLD_DATA=true
434 export NODE_PATH=${tailwindcss-plugins}
435 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
436 '';
437 in {
438 watch-appview = {
439 type = "app";
440 program = toString (pkgs.writeShellScript "watch-appview" ''
441 echo "copying static files to appview/pages/static..."
442 mkdir -p appview/pages/static
443 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
444 ${air-watcher "appview" ""}/bin/run
445 '');
446 };
447 watch-knot = {
448 type = "app";
449 program = ''${air-watcher "knot" "server"}/bin/run'';
450 };
451 watch-spindle = {
452 type = "app";
453 program = ''${air-watcher "spindle" ""}/bin/run'';
454 };
455 watch-blog = {
456 type = "app";
457 program = toString (pkgs.writeShellScript "watch-blog" ''
458 echo "copying static files to appview/pages/static..."
459 mkdir -p appview/pages/static
460 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
461 ${air-watcher "blog" "serve"}/bin/run
462 '');
463 };
464 watch-tailwind = {
465 type = "app";
466 program = ''${tailwind-watcher}/bin/run'';
467 };
468 serve-docs = {
469 type = "app";
470 program = toString (pkgs.writeShellScript "serve-docs" ''
471 echo "building docs..."
472 docsOut=$(nix build --no-link --print-out-paths .#docs)
473 echo "serving docs at http://localhost:1414"
474 cd "$docsOut"
475 exec ${pkgs.python3}/bin/python3 -m http.server 1414
476 '');
477 };
478 regenerate-proto = {
479 type = "app";
480 program =
481 (pkgs.writeShellApplication {
482 name = "regenerate-proto";
483 runtimeInputs = with pkgs; [git buf coreutils];
484 text = ''
485 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
486 cd "$rootDir"
487 echo ">>> regenerating protobuf files.."
488 buf generate
489 echo ">>> generating file descriptor set for shuttle..."
490 buf build -o shuttle/src/gen/file_descriptor_set.bin
491 echo ">>> done"
492 '';
493 })
494 + "/bin/regenerate-proto";
495 };
496 vm = let
497 guestSystem =
498 if pkgs.stdenv.hostPlatform.isAarch64
499 then "aarch64-linux"
500 else "x86_64-linux";
501 in {
502 type = "app";
503 program =
504 (pkgs.writeShellApplication {
505 name = "launch-vm";
506 text = ''
507 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
508 cd "$rootDir"
509
510 # Reset TMPDIR in case it points to a stale nix-shell temp dir
511 export TMPDIR=/tmp
512
513 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
514
515 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
516 exec ${pkgs.lib.getExe
517 (import ./nix/vm.nix {
518 inherit nixpkgs self;
519 system = guestSystem;
520 hostSystem = system;
521 }).config.system.build.vm}
522 '';
523 })
524 + /bin/launch-vm;
525 };
526 gomod2nix = {
527 type = "app";
528 program = toString (pkgs.writeShellScript "gomod2nix" ''
529 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
530 '');
531 };
532 lexgen = {
533 type = "app";
534 program =
535 (pkgs.writeShellApplication {
536 name = "lexgen";
537 text = ''
538 if ! command -v lexgen > /dev/null; then
539 echo "error: must be executed from devshell"
540 exit 1
541 fi
542
543 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
544 cd "$rootDir"
545
546 # *_ext.go are hand-written extensions; never remove or mutate them
547 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
548 lexgen --build-file lexicon-build-config.json lexicons
549
550 # disable type registration temporarily while running cborgen
551 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
552 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
553 # lexgen generates incomplete Marshaler/Unmarshaler for union types
554 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -not -name "cbor_gen.go" -exec \
555 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
556 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
557 ${pkgs.gotools}/bin/goimports -w api/tangled/*
558 CGO_ENABLED=0 go run ./cmd/cborgen/
559 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
560
561 lexgen --build-file lexicon-build-config.json lexicons
562 rm api/tangled/*.bak
563 '';
564 })
565 + /bin/lexgen;
566 };
567 });
568
569 nixosModules.appview = {
570 lib,
571 pkgs,
572 ...
573 }: {
574 imports = [./nix/modules/appview.nix];
575
576 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
577 };
578 nixosModules.knotmirror = {
579 lib,
580 pkgs,
581 ...
582 }: {
583 imports = [./nix/modules/knotmirror.nix];
584
585 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
586 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
587 };
588 nixosModules.zoekt-tnglserver = {
589 lib,
590 pkgs,
591 ...
592 }: {
593 imports = [./nix/modules/zoekt-tnglserver.nix];
594
595 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
596 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
597 };
598 nixosModules.knot = {
599 lib,
600 pkgs,
601 ...
602 }: {
603 imports = [./nix/modules/knot.nix];
604
605 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
606 };
607 nixosModules.spindle = {
608 lib,
609 pkgs,
610 ...
611 }: {
612 imports = [./nix/modules/spindle.nix];
613
614 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
615 };
616 nixosModules.shuttle = {
617 lib,
618 pkgs,
619 ...
620 }: {
621 imports = [./nix/modules/shuttle.nix];
622
623 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
624 };
625
626 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
627
628 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
629
630 nixosConfigurations = let
631 spindleNixosBase = nixpkgs.lib.nixosSystem {
632 system = "x86_64-linux";
633 modules = [self.nixosModules.spindle-nixos];
634 };
635 in {
636 spindle-nixos = spindleNixosBase;
637 };
638 };
639}