tangled.org
Monorepo for Tangled
tangled.org
23 kB
667 lines
1{
2 description = "atproto github";
3
4 inputs = {
5 nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
6 microvm = {
7 url = "github:microvm-nix/microvm.nix";
8 inputs.nixpkgs.follows = "nixpkgs";
9 };
10 fenix = {
11 url = "github:nix-community/fenix";
12 inputs.nixpkgs.follows = "nixpkgs";
13 };
14 gomod2nix = {
15 url = "github:nix-community/gomod2nix";
16 inputs.nixpkgs.follows = "nixpkgs";
17 };
18 flake-compat = {
19 url = "https://git.lix.systems/lix-project/flake-compat/archive/main.tar.gz";
20 flake = false;
21 };
22 indigo = {
23 url = "github:oppiliappan/indigo";
24 flake = false;
25 };
26 htmx-src = {
27 url = "https://cdn.jsdelivr.net/npm/htmx.org@2.0.10/dist/htmx.min.js";
28 flake = false;
29 };
30 htmx-ws-src = {
31 url = "https://cdn.jsdelivr.net/npm/htmx-ext-ws@2.0.4";
32 flake = false;
33 };
34 lucide-src = {
35 url = "https://github.com/lucide-icons/lucide/releases/download/0.536.0/lucide-icons-0.536.0.zip";
36 flake = false;
37 };
38 inter-fonts-src = {
39 url = "https://github.com/rsms/inter/releases/download/v4.1/Inter-4.1.zip";
40 flake = false;
41 };
42 actor-typeahead-src = {
43 url = "git+https://tangled.org/@jakelazaroff.com/actor-typeahead";
44 flake = false;
45 };
46 mermaid-src = {
47 url = "https://cdn.jsdelivr.net/npm/mermaid@11.12.3/dist/mermaid.min.js";
48 flake = false;
49 };
50 hls-src = {
51 url = "https://cdn.jsdelivr.net/npm/hls.js@1.5.13/dist/hls.min.js";
52 flake = false;
53 };
54 mathjax-src = {
55 url = "https://cdn.jsdelivr.net/npm/mathjax@4.1.2/tex-svg.js";
56 flake = false;
57 };
58 tailwindcss-animated-src = {
59 url = "https://registry.npmjs.org/tailwindcss-animated/-/tailwindcss-animated-1.1.2.tgz";
60 flake = false;
61 };
62 ibm-plex-mono-src = {
63 url = "https://github.com/IBM/plex/releases/download/%40ibm%2Fplex-mono%401.1.0/ibm-plex-mono.zip";
64 flake = false;
65 };
66 sqlite-lib-src = {
67 url = "https://sqlite.org/2024/sqlite-amalgamation-3450100.zip";
68 flake = false;
69 };
70 fetch-tangled = {
71 url = "git+https://tangled.org/isabelroses.com/fetch-tangled";
72 inputs.nixpkgs.follows = "nixpkgs";
73 };
74 };
75
76 outputs = {
77 self,
78 nixpkgs,
79 fenix,
80 gomod2nix,
81 indigo,
82 htmx-src,
83 htmx-ws-src,
84 lucide-src,
85 inter-fonts-src,
86 sqlite-lib-src,
87 ibm-plex-mono-src,
88 actor-typeahead-src,
89 mermaid-src,
90 hls-src,
91 microvm,
92 fetch-tangled,
93 mathjax-src,
94 tailwindcss-animated-src,
95 ...
96 }: let
97 supportedSystems = ["x86_64-linux" "x86_64-darwin" "aarch64-linux" "aarch64-darwin"];
98 forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
99 nixpkgsFor = forAllSystems (system:
100 import nixpkgs {
101 inherit system;
102 overlays = [fetch-tangled.overlays.default];
103 });
104
105 mkPackageSet = pkgs:
106 pkgs.lib.makeScope pkgs.newScope (self: {
107 src = let
108 fs = pkgs.lib.fileset;
109 in
110 fs.toSource {
111 root = ./.;
112 fileset = fs.difference (fs.intersection (fs.gitTracked ./.) (fs.fileFilter (file: !(file.hasExt "nix")) ./.)) (fs.maybeMissing ./.jj);
113 };
114 rustSrc = let
115 fs = pkgs.lib.fileset;
116 in
117 fs.toSource {
118 root = ./.;
119 fileset =
120 fs.intersection
121 (fs.fromSource self.src)
122 (fs.unions [
123 ./Cargo.toml
124 ./Cargo.lock
125 ./shuttle
126 ./bobbin
127 ]);
128 };
129 buildGoApplication =
130 (self.callPackage "${gomod2nix}/builder" {
131 gomod2nix = gomod2nix.legacyPackages.${pkgs.stdenv.hostPlatform.system}.gomod2nix;
132 }).buildGoApplication;
133 rustPlatform = pkgs.makeRustPlatform {
134 inherit (fenix.packages.${pkgs.stdenv.hostPlatform.system}.stable) rustc cargo;
135 };
136 rustPlatformStatic = let
137 system = pkgs.stdenv.hostPlatform.system;
138 muslTarget = pkgs.pkgsStatic.stdenv.hostPlatform.rust.rustcTarget;
139 toolchain = fenix.packages.${system}.combine [
140 fenix.packages.${system}.stable.cargo
141 fenix.packages.${system}.stable.rustc
142 fenix.packages.${system}.targets.${muslTarget}.stable.rust-std
143 ];
144 in
145 pkgs.pkgsStatic.makeRustPlatform {
146 cargo = toolchain;
147 rustc = toolchain;
148 };
149 modules = ./nix/gomod2nix.toml;
150 sqlite-lib = self.callPackage ./nix/pkgs/sqlite-lib.nix {
151 inherit sqlite-lib-src;
152 };
153 lexgen = self.callPackage ./nix/pkgs/lexgen.nix {inherit indigo;};
154 goat = self.callPackage ./nix/pkgs/goat.nix {inherit indigo;};
155 appview-static-files = self.callPackage ./nix/pkgs/appview-static-files.nix {
156 inherit htmx-src htmx-ws-src lucide-src inter-fonts-src ibm-plex-mono-src actor-typeahead-src mermaid-src hls-src mathjax-src tailwindcss-animated-src;
157 };
158 web-static-files = self.callPackage ./nix/pkgs/web-static-files.nix {
159 inherit inter-fonts-src ibm-plex-mono-src;
160 };
161 appview = self.callPackage ./nix/pkgs/appview.nix {};
162 blog = self.callPackage ./nix/pkgs/blog.nix {};
163 docs = self.callPackage ./nix/pkgs/docs.nix {
164 inherit inter-fonts-src ibm-plex-mono-src lucide-src;
165 inherit (pkgs) pagefind;
166 };
167 spindle = self.callPackage ./nix/pkgs/spindle.nix {};
168 shuttle = self.callPackage ./nix/pkgs/shuttle.nix {
169 src = self.rustSrc;
170 };
171 shuttle-static = self.callPackage ./nix/pkgs/shuttle.nix {
172 src = self.rustSrc;
173 rustPlatform = self.rustPlatformStatic;
174 };
175 knot-unwrapped = self.callPackage ./nix/pkgs/knot-unwrapped.nix {};
176 knot = self.callPackage ./nix/pkgs/knot.nix {};
177 dolly = self.callPackage ./nix/pkgs/dolly.nix {};
178 tap = self.callPackage ./nix/pkgs/tap.nix {};
179 knotmirror = self.callPackage ./nix/pkgs/knotmirror.nix {};
180 bobbin = self.callPackage ./nix/pkgs/bobbin.nix {};
181 zoekt-webserver = self.callPackage ./nix/pkgs/zoekt-webserver.nix {};
182 zoekt-tngl-indexserver = self.callPackage ./nix/pkgs/zoekt-tngl-indexserver.nix {};
183 });
184 in {
185 overlays.default = final: prev: {
186 inherit
187 (mkPackageSet final)
188 lexgen
189 goat
190 sqlite-lib
191 spindle
192 shuttle
193 knot-unwrapped
194 knot
195 appview
196 docs
197 dolly
198 tap
199 knotmirror
200 bobbin
201 zoekt-webserver
202 zoekt-tngl-indexserver
203 ;
204 };
205
206 packages = forAllSystems (system: let
207 pkgs = nixpkgsFor.${system};
208 linuxPkgs = nixpkgsFor."x86_64-linux";
209 packages = mkPackageSet pkgs;
210 staticPackages = mkPackageSet pkgs.pkgsStatic;
211 crossPackages = mkPackageSet pkgs.pkgsCross.gnu64.pkgsStatic;
212 in {
213 inherit
214 (packages)
215 appview
216 appview-static-files
217 web-static-files
218 blog
219 lexgen
220 goat
221 spindle
222 knot
223 knot-unwrapped
224 sqlite-lib
225 docs
226 shuttle
227 shuttle-static
228 dolly
229 tap
230 knotmirror
231 bobbin
232 zoekt-webserver
233 zoekt-tngl-indexserver
234 ;
235
236 pkgsStatic-appview = staticPackages.appview;
237 pkgsStatic-knot = staticPackages.knot;
238 pkgsStatic-knot-unwrapped = staticPackages.knot-unwrapped;
239 pkgsStatic-spindle = staticPackages.spindle;
240 pkgsStatic-sqlite-lib = staticPackages.sqlite-lib;
241 pkgsStatic-dolly = staticPackages.dolly;
242
243 pkgsCross-gnu64-pkgsStatic-appview = crossPackages.appview;
244 pkgsCross-gnu64-pkgsStatic-knot = crossPackages.knot;
245 pkgsCross-gnu64-pkgsStatic-knot-unwrapped = crossPackages.knot-unwrapped;
246 pkgsCross-gnu64-pkgsStatic-spindle = crossPackages.spindle;
247 pkgsCross-gnu64-pkgsStatic-dolly = crossPackages.dolly;
248
249 treefmt-wrapper = pkgs.treefmt.withConfig {
250 settings.formatter = {
251 alejandra = {
252 command = pkgs.lib.getExe pkgs.alejandra;
253 includes = ["*.nix"];
254 };
255
256 gofmt = {
257 command = pkgs.lib.getExe' pkgs.go "gofmt";
258 options = ["-w"];
259 includes = ["*.go"];
260 };
261
262 rustfmt = {
263 command = pkgs.lib.getExe' fenix.packages.${system}.stable.rustfmt "rustfmt";
264 options = ["--edition" "2024"];
265 includes = ["*.rs"];
266 excludes = ["**/src/_lex/**"];
267 };
268
269 prettier = {
270 command = pkgs.writeShellScript "prettier-wrapper" ''
271 cd web
272 args=()
273 for arg in "$@"; do
274 if [[ "$arg" == web/* ]]; then
275 args+=("''${arg#web/}")
276 else
277 args+=("$arg")
278 fi
279 done
280 exec ${pkgs.lib.getExe pkgs.prettier} "''${args[@]}"
281 '';
282 options = ["-w"];
283 includes = [
284 "web/**/*.cjs"
285 "web/**/*.css"
286 "web/**/*.html"
287 "web/**/*.js"
288 "web/**/*.json"
289 "web/**/*.json5"
290 "web/**/*.jsx"
291 "web/**/*.mdx"
292 "web/**/*.mjs"
293 "web/**/*.scss"
294 "web/**/*.ts"
295 "web/**/*.tsx"
296 "web/**/*.vue"
297 "web/**/*.yaml"
298 "web/**/*.yml"
299 ];
300 excludes = [
301 "web/static/**"
302 "web/src/lib/api/lexicons/**"
303 ];
304 };
305 };
306 };
307
308 spindle-nixos-image = linuxPkgs.callPackage ./nix/pkgs/spindle-nixos-image.nix {
309 nixosSystem = self.nixosConfigurations.spindle-nixos;
310 };
311 spindle-nixos-image-tarball = linuxPkgs.runCommand "spindle-nixos-image-tarball.tar.gz" {} ''
312 tar -S -C ${self.packages.${system}.spindle-nixos-image} -h -czf $out .
313 '';
314
315 spindle-alpine-image = let
316 branch = "3.24";
317 version = "${branch}.0";
318 arch = "x86_64";
319 cdn = "https://dl-cdn.alpinelinux.org/alpine/v${branch}/releases/${arch}";
320
321 shuttle = (mkPackageSet linuxPkgs).shuttle-static;
322 in
323 linuxPkgs.callPackage ./nix/pkgs/spindle-alpine-image.nix {
324 inherit arch shuttle;
325 repositories = [
326 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/main"
327 "https://dl-cdn.alpinelinux.org/alpine/v${branch}/community"
328 ];
329 rootfs = linuxPkgs.fetchurl {
330 url = "${cdn}/alpine-minirootfs-${version}-${arch}.tar.gz";
331 hash = "sha256-3poRwODn6clNs+2K97RQ6vwLE2h71+kZnVUFDyCqCok=";
332 };
333 kernel = linuxPkgs.fetchurl {
334 url = "${cdn}/netboot-${version}/vmlinuz-virt";
335 hash = "sha256-Hmv5Ancgx1w+0NeRcfIbV5HuQMqXldB8fG4E3F6irpA=";
336 };
337 initramfs = linuxPkgs.fetchurl {
338 url = "${cdn}/netboot-${version}/initramfs-virt";
339 hash = "sha256-ZCWGSaVMOYOmLz1Gwsf2RhYarMqk+tFVA6MMDWiHVJQ=";
340 };
341 modloop = linuxPkgs.fetchurl {
342 url = "${cdn}/netboot-${version}/modloop-virt";
343 hash = "sha256-p3yO7yU28k04iT01sOzhDmEYi+Yl7VZs5r3RYsWCBX0=";
344 };
345 };
346 spindle-alpine-image-tarball = linuxPkgs.runCommand "spindle-alpine-image-tarball.tar.gz" {} ''
347 tar -S -C ${self.packages.${system}.spindle-alpine-image} -h -czf $out .
348 '';
349 });
350 defaultPackage = forAllSystems (system: self.packages.${system}.appview);
351 devShells = forAllSystems (system: let
352 pkgs = nixpkgsFor.${system};
353 packages' = self.packages.${system};
354 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
355 {
356 name = "tailwindcss-animated";
357 path = tailwindcss-animated-src;
358 }
359 ];
360 staticShell = args:
361 (pkgs.mkShell.override {
362 stdenv = pkgs.pkgsStatic.stdenv;
363 }) (args
364 // {
365 nativeBuildInputs =
366 args.nativeBuildInputs
367 ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [
368 pkgs.darwin.cctools
369 ];
370 });
371 in {
372 default = staticShell {
373 nativeBuildInputs =
374 [
375 pkgs.go
376 pkgs.air
377 pkgs.gopls
378 pkgs.httpie
379 pkgs.litecli
380 pkgs.websocat
381 pkgs.tailwindcss
382 pkgs.nixos-shell
383 pkgs.redis
384 pkgs.worker-build
385 pkgs.cargo-generate
386 pkgs.qemu
387 pkgs.cdrkit
388 pkgs.buf
389 pkgs.protobuf
390 pkgs.protoc-gen-prost
391 pkgs.protoc-gen-prost-crate
392 pkgs.protoc-gen-prost-serde
393 pkgs.protoc-gen-go
394 (fenix.packages.${system}.combine [
395 fenix.packages.${system}.stable.cargo
396 fenix.packages.${system}.stable.rustc
397 fenix.packages.${system}.stable.rust-src
398 fenix.packages.${system}.stable.clippy
399 fenix.packages.${system}.stable.rustfmt
400 fenix.packages.${system}.stable.rust-analyzer
401 fenix.packages.${system}.targets.wasm32-unknown-unknown.stable.rust-std
402 ])
403 pkgs.coreutils # for those of us who are on systems that use busybox (alpine)
404 packages'.lexgen
405 packages'.treefmt-wrapper
406 packages'.tap
407 pkgs.e2fsprogs
408 pkgs.util-linux
409 pkgs.pnpm
410 pkgs.nodejs
411 ]
412 ++ pkgs.lib.optionals pkgs.stdenv.isLinux [
413 pkgs.parted
414 pkgs.slirp4netns
415 pkgs.iproute2
416 ];
417 shellHook = ''
418 export CC=${pkgs.stdenv.cc}/bin/cc
419 export NODE_PATH=${tailwindcss-plugins}''${NODE_PATH:+:$NODE_PATH}
420 (
421 cd "$(git rev-parse --show-toplevel 2>/dev/null || pwd)"
422 mkdir -p appview/pages/static
423 # temporary self-heal for workspaces that copied static assets as read-only
424 [ -d appview/pages/static/icons ] && [ ! -w appview/pages/static/icons ] && chmod -R u+rwX appview/pages/static
425 # no preserve is needed because watch-tailwind will want to be able to overwrite
426 cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
427 mkdir -p web/static
428 rm -rf web/static/fonts web/static/logos
429 cp -fr --no-preserve=ownership,mode ${packages'.web-static-files}/* web/static
430 )
431 export TANGLED_OAUTH_CLIENT_KID="$(date +%s)"
432 export TANGLED_OAUTH_CLIENT_SECRET="$(${packages'.goat}/bin/goat key generate -t P-256 | grep -A1 "Secret Key" | tail -n1 | awk '{print $1}')"
433 # Make xcrun (Nix stub) able to find ld from the system Command Line Tools.
434 # Without this, worker-build/cargo fails with "error: tool 'ld' not found".
435 if [ -d /Library/Developer/CommandLineTools/usr/bin ]; then
436 export PATH=/Library/Developer/CommandLineTools/usr/bin:$PATH
437 fi
438 '';
439 env.CGO_ENABLED = 1;
440 };
441 });
442 apps = forAllSystems (system: let
443 pkgs = nixpkgsFor."${system}";
444 packages' = self.packages.${system};
445 tailwindcss-plugins = pkgs.linkFarm "tailwindcss-plugins" [
446 {
447 name = "tailwindcss-animated";
448 path = tailwindcss-animated-src;
449 }
450 ];
451 air-watcher = name: arg:
452 pkgs.writeShellScriptBin "run"
453 ''
454 export PATH=${pkgs.go}/bin:$PATH
455 ${pkgs.air}/bin/air -c ./.air/${name}.toml \
456 -build.args_bin "${arg}"
457 '';
458 tailwind-watcher =
459 pkgs.writeShellScriptBin "run"
460 ''
461 export BROWSERSLIST_IGNORE_OLD_DATA=true
462 export NODE_PATH=${tailwindcss-plugins}
463 ${pkgs.tailwindcss}/bin/tailwindcss --watch=always -i input.css -o ./appview/pages/static/tw.css
464 '';
465 in {
466 watch-appview = {
467 type = "app";
468 program = toString (pkgs.writeShellScript "watch-appview" ''
469 echo "copying static files to appview/pages/static..."
470 mkdir -p appview/pages/static
471 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
472 ${air-watcher "appview" ""}/bin/run
473 '');
474 };
475 watch-knot = {
476 type = "app";
477 program = ''${air-watcher "knot" "server"}/bin/run'';
478 };
479 watch-spindle = {
480 type = "app";
481 program = ''${air-watcher "spindle" ""}/bin/run'';
482 };
483 watch-blog = {
484 type = "app";
485 program = toString (pkgs.writeShellScript "watch-blog" ''
486 echo "copying static files to appview/pages/static..."
487 mkdir -p appview/pages/static
488 ${pkgs.coreutils}/bin/cp -fr --no-preserve=ownership,mode ${packages'.appview-static-files}/* appview/pages/static
489 ${air-watcher "blog" "serve"}/bin/run
490 '');
491 };
492 watch-tailwind = {
493 type = "app";
494 program = ''${tailwind-watcher}/bin/run'';
495 };
496 serve-docs = {
497 type = "app";
498 program = toString (pkgs.writeShellScript "serve-docs" ''
499 echo "building docs..."
500 docsOut=$(nix build --no-link --print-out-paths .#docs)
501 echo "serving docs at http://localhost:1414"
502 cd "$docsOut"
503 exec ${pkgs.python3}/bin/python3 -m http.server 1414
504 '');
505 };
506 regenerate-proto = {
507 type = "app";
508 program =
509 (pkgs.writeShellApplication {
510 name = "regenerate-proto";
511 runtimeInputs = with pkgs; [git buf coreutils];
512 text = ''
513 rootDir=$(git rev-parse --show-toplevel 2>/dev/null || pwd)
514 cd "$rootDir"
515 echo ">>> regenerating protobuf files.."
516 buf generate
517 echo ">>> generating file descriptor set for shuttle..."
518 buf build -o shuttle/src/gen/file_descriptor_set.bin
519 echo ">>> done"
520 '';
521 })
522 + "/bin/regenerate-proto";
523 };
524 vm = let
525 guestSystem =
526 if pkgs.stdenv.hostPlatform.isAarch64
527 then "aarch64-linux"
528 else "x86_64-linux";
529 in {
530 type = "app";
531 program =
532 (pkgs.writeShellApplication {
533 name = "launch-vm";
534 text = ''
535 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
536 cd "$rootDir"
537
538 # Reset TMPDIR in case it points to a stale nix-shell temp dir
539 export TMPDIR=/tmp
540
541 mkdir -p nix/vm-data/{knot,repos,spindle,spindle-logs}
542
543 export TANGLED_VM_DATA_DIR="$rootDir/nix/vm-data"
544 exec ${pkgs.lib.getExe
545 (import ./nix/vm.nix {
546 inherit nixpkgs self;
547 system = guestSystem;
548 hostSystem = system;
549 }).config.system.build.vm}
550 '';
551 })
552 + /bin/launch-vm;
553 };
554 gomod2nix = {
555 type = "app";
556 program = toString (pkgs.writeShellScript "gomod2nix" ''
557 ${gomod2nix.legacyPackages.${system}.gomod2nix}/bin/gomod2nix generate --outdir ./nix
558 '');
559 };
560 lexgen = {
561 type = "app";
562 program =
563 (pkgs.writeShellApplication {
564 name = "lexgen";
565 text = ''
566 if ! command -v lexgen > /dev/null; then
567 echo "error: must be executed from devshell"
568 exit 1
569 fi
570
571 rootDir=$(jj --ignore-working-copy root || git rev-parse --show-toplevel) || (echo "error: can't find repo root?"; exit 1)
572 cd "$rootDir"
573
574 # *_ext.go are hand-written extensions; never remove or mutate them
575 find api/tangled -maxdepth 1 -type f -not -name '*_ext.go' -delete
576 lexgen --build-file lexicon-build-config.json lexicons
577
578 # disable type registration temporarily while running cborgen
579 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -exec \
580 sed -i.bak 's/\tutil/\/\/\tutil/' {} +
581 # lexgen generates incomplete Marshaler/Unmarshaler for union types
582 find api/tangled -maxdepth 1 -name '*.go' -not -name '*_ext.go' -not -name "cbor_gen.go" -exec \
583 sed -i '/^func.*\(MarshalCBOR\|UnmarshalCBOR\)/,/^}/ s/^/\/\/ /' {} +
584 for f in api/tangled/*_ext.go; do [ -e "''$f" ] && mv "''$f" "''$f.bak"; done
585 ${pkgs.gotools}/bin/goimports -w api/tangled/*
586 CGO_ENABLED=0 go run ./cmd/cborgen/
587 for f in api/tangled/*_ext.go.bak; do [ -e "''$f" ] && mv "''$f" "''${f%.bak}"; done
588
589 lexgen --build-file lexicon-build-config.json lexicons
590 rm api/tangled/*.bak
591 '';
592 })
593 + /bin/lexgen;
594 };
595 });
596
597 nixosModules.appview = {
598 lib,
599 pkgs,
600 ...
601 }: {
602 imports = [./nix/modules/appview.nix];
603
604 services.tangled.appview.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.appview;
605 };
606 nixosModules.knotmirror = {
607 lib,
608 pkgs,
609 ...
610 }: {
611 imports = [./nix/modules/knotmirror.nix];
612
613 services.tangled.knotmirror.tap-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.tap;
614 services.tangled.knotmirror.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knotmirror;
615 };
616 nixosModules.zoekt-tnglserver = {
617 lib,
618 pkgs,
619 ...
620 }: {
621 imports = [./nix/modules/zoekt-tnglserver.nix];
622
623 services.tangled.zoekt.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-tngl-indexserver;
624 services.tangled.zoekt.zoekt-webserver-package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.zoekt-webserver;
625 };
626 nixosModules.knot = {
627 lib,
628 pkgs,
629 ...
630 }: {
631 imports = [./nix/modules/knot.nix];
632
633 services.tangled.knot.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.knot;
634 };
635 nixosModules.spindle = {
636 lib,
637 pkgs,
638 ...
639 }: {
640 imports = [./nix/modules/spindle.nix];
641
642 services.tangled.spindle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.spindle;
643 };
644 nixosModules.shuttle = {
645 lib,
646 pkgs,
647 ...
648 }: {
649 imports = [./nix/modules/shuttle.nix];
650
651 services.tangled.shuttle.package = lib.mkDefault self.packages.${pkgs.stdenv.hostPlatform.system}.shuttle;
652 };
653
654 nixosModules.spindle-nixos = import ./nix/microvm/spindle-vm.nix {inherit self microvm;} ./nix/microvm/qemu.nix;
655
656 formatter = forAllSystems (system: self.packages.${system}.treefmt-wrapper);
657
658 nixosConfigurations = let
659 spindleNixosBase = nixpkgs.lib.nixosSystem {
660 system = "x86_64-linux";
661 modules = [self.nixosModules.spindle-nixos];
662 };
663 in {
664 spindle-nixos = spindleNixosBase;
665 };
666 };
667}