vm.fail
ACPI AML decompiler w/ CFG recovery and structured pseudocode
3.0 kB
79 lines
1cmake_minimum_required(VERSION 3.16)
2project(tobi VERSION 0.1.0 LANGUAGES C)
3
4option(TOBI_WERROR "Build with warnings as errors" ON)
5option(TOBI_SAN "Build with AddressSanitizer and UndefinedBehaviorSanitizer" OFF)
6option(TOBI_FZ "Build fuzz smoke target" ON)
7option(TOBI_LIBFUZZER "Build LLVM libFuzzer target" OFF)
8
9set(CMAKE_C_STANDARD 11)
10set(CMAKE_C_STANDARD_REQUIRED ON)
11set(CMAKE_C_EXTENSIONS OFF)
12
13set(TOBI_COMMON
14 src/rd.c src/p.c src/op.c src/nm.c src/ir.c src/cf.c src/dc.c
15 src/da.c src/dg.c src/js.c src/mem.c src/str.c)
16
17add_library(tobilib ${TOBI_COMMON})
18target_include_directories(tobilib PUBLIC ${CMAKE_CURRENT_SOURCE_DIR}/src)
19target_compile_definitions(tobilib PUBLIC _POSIX_C_SOURCE=200809L)
20
21add_executable(tobi src/main.c)
22target_link_libraries(tobi PRIVATE tobilib)
23
24set(TOBI_WARN -Wall -Wextra -Wpedantic)
25if(TOBI_WERROR)
26 list(APPEND TOBI_WARN -Werror)
27endif()
28target_compile_options(tobilib PRIVATE ${TOBI_WARN})
29target_compile_options(tobi PRIVATE ${TOBI_WARN})
30
31if(TOBI_SAN)
32 set(SAN_FLAGS -fsanitize=address,undefined -fno-omit-frame-pointer)
33 target_compile_definitions(tobilib PUBLIC TOBI_SAN_BUILD=1)
34 target_compile_options(tobilib PRIVATE ${SAN_FLAGS})
35 target_compile_options(tobi PRIVATE ${SAN_FLAGS})
36 target_link_options(tobi PRIVATE ${SAN_FLAGS})
37 target_link_options(tobilib INTERFACE ${SAN_FLAGS})
38endif()
39
40enable_testing()
41
42add_executable(tobi_test
43 test/main.c test/t_rd.c test/t_nm.c test/t_p.c test/t_ir.c
44 test/t_cf.c test/t_da.c test/t_dc.c test/t_js.c test/t_bad.c test/t_cli.c
45 test/t_prod.c test/t_corpus.c test/t_snap.c)
46target_link_libraries(tobi_test PRIVATE tobilib)
47target_compile_options(tobi_test PRIVATE ${TOBI_WARN})
48target_compile_definitions(tobi_test PRIVATE
49 TOBI_BIN="$<TARGET_FILE:tobi>"
50 TOBI_SRC_DIR="${CMAKE_CURRENT_SOURCE_DIR}")
51if(TOBI_SAN)
52 target_compile_options(tobi_test PRIVATE ${SAN_FLAGS})
53 target_link_options(tobi_test PRIVATE ${SAN_FLAGS})
54endif()
55
56foreach(t rd nm p ir cf da dc js bad cli prod corpus snap)
57 add_test(NAME ${t} COMMAND tobi_test ${t})
58endforeach()
59
60if(TOBI_FZ)
61 add_executable(fz fuzz/fz.c)
62 target_link_libraries(fz PRIVATE tobilib)
63 target_compile_options(fz PRIVATE ${TOBI_WARN})
64 target_compile_definitions(fz PRIVATE TOBI_SRC_DIR="${CMAKE_CURRENT_SOURCE_DIR}")
65 if(TOBI_SAN)
66 target_compile_options(fz PRIVATE ${SAN_FLAGS})
67 target_link_options(fz PRIVATE ${SAN_FLAGS})
68 endif()
69endif()
70
71if(TOBI_LIBFUZZER)
72 set(LIBFUZZER_COMPILE_FLAGS -fsanitize=fuzzer-no-link,address,undefined -fno-omit-frame-pointer)
73 target_compile_definitions(tobilib PUBLIC TOBI_SAN_BUILD=1)
74 target_compile_options(tobilib PRIVATE ${LIBFUZZER_COMPILE_FLAGS})
75 add_executable(fz_llvm fuzz/lf.c)
76 target_link_libraries(fz_llvm PRIVATE tobilib)
77 target_compile_options(fz_llvm PRIVATE ${TOBI_WARN} -fsanitize=fuzzer,address,undefined -fno-omit-frame-pointer)
78 target_link_options(fz_llvm PRIVATE -fsanitize=fuzzer,address,undefined -fno-omit-frame-pointer)
79endif()